Do not install files to /usr/local

Thanks for the help <3

---
Your package xmap-git [1] has been flagged out-of-date by xiota [2]:

This package is installing files to `/usr/local`.  Probably need to
add `-DCMAKE_INSTALL_PREFIX='/usr'` to `cmake` in `build()`.

[1] https://aur.archlinux.org/pkgbase/xmap-git/
[2] https://aur.archlinux.org/account/xiota/
---

2 files changed, 27 insertions, 14 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 72fd7cd5f92d..df47bb1743c0 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,7 +1,7 @@
 pkgbase = xmap-git
 	pkgdesc = Fast Internet-wide IPv6 & IPv4 network scanner
-	pkgver = 2.0.0.r0.g8461c6a
-	pkgrel = 1
+	pkgver = 2.0.0.r15.gf30b823
+	pkgrel = 2
 	url = https://github.com/idealeer/xmap
 	arch = x86_64
 	license = Apache
diff --git a/PKGBUILD b/PKGBUILD
index 0e24eb8da1cb..c7b80b282a7b 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,31 +1,44 @@
 # Maintainer: Stefen Wakefield <me@xstefen.dev>
-pkgname=xmap-git
-pkgver=2.0.0.r0.g8461c6a
-pkgrel=1
+_pkgname="xmap"
+pkgname="$_pkgname-git"
+pkgver=2.0.0.r15.gf30b823
+pkgrel=2
 pkgdesc="Fast Internet-wide IPv6 & IPv4 network scanner"
 arch=('x86_64')
 url="https://github.com/idealeer/xmap"
 license=('Apache')
 depends=('gmp' 'gengetopt' 'libpcap' 'json-c' 'libunistring')
 makedepends=('cmake' 'flex' 'byacc' 'git')
-conflicts=("${pkgname%-git}")
-provides=("${pkgname%-git}")
+conflicts=("$_pkgname")
+provides=("$_pkgname")
+
+_pkgsrc="$_pkgname"
 source=("git+https://github.com/idealeer/xmap.git")
 sha256sums=('SKIP')
 
 pkgver() {
-  cd "$srcdir/${pkgname%-git}"
+  cd "$_pkgsrc"
   git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
+prepare() {
+  sed -E 's|DESTINATION sbin|DESTINATION bin|' -i "$_pkgsrc/src/CMakeLists.txt"
+}
+
 build() {
-	cd "$srcdir/${pkgname%-git}"
-    cmake -DENABLE_DEVELOPMENT=OFF -DENABLE_LOG_TRACE=OFF .
-    make    
+  local _cmake_options=(
+    -B build
+    -S "$_pkgsrc"
+    -DCMAKE_INSTALL_PREFIX='/usr'
+    -DENABLE_DEVELOPMENT=OFF
+    -DENABLE_LOG_TRACE=OFF
+    -Wno-dev
+  )
+  cmake "${_cmake_options[@]}"
+  cmake --build build
 }
 
 package() {
-	cd "$srcdir/${pkgname%-git}"
-	make DESTDIR="$pkgdir/" install
-    install -D -m644 "${srcdir}/${pkgname%-git}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+  DESTDIR="${pkgdir:?}" cmake --install build
+  install -Dm644 "$_pkgsrc/LICENSE" -t "${pkgdir:?}/usr/share/licenses/$pkgname/"
 }