Version update to 5.3.1. Patch to nm.py is no longer needed (Fix include distro which is supported in recent versions).

1 files changed, 40 insertions, 31 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 656cae1f6ae2..ceb9af4e686a 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,41 +1,50 @@
 # Maintainer: Pawel Mosakowski <pawel at mosakowski dot net>
+# Maintainer: Fredy García <frealgagu at gmail dot com>
+
 pkgname=appgate-sdp
-conflicts=('appgate-sdp-headless' 'appgate-sdp-5')
-pkgver=4.3.2
-_download_pkgver=4.3
+pkgver=5.3.1
 pkgrel=1
-epoch=
-pkgdesc="Software Defined Perimeter - GUI client"
-arch=('x86_64')
-url="https://www.cyxtera.com/essential-defense/appgate-sdp/support"
-license=('custom')
-
-# dependecies calculated by namcap
-depends=('gconf' 'libsecret' 'gtk3' 'python' 'nss' 'libxss' 'nodejs' 'dnsmasq')
-source=("https://sdpdownloads.cyxtera.com/AppGate-SDP-${_download_pkgver}/clients/${pkgname}_${pkgver}_amd64.deb"
-        "appgatedriver.service"
-        "nm.py.patch")
-
+pkgdesc="Appgate SDP (Software Defined Perimeter) desktop client"
+arch=("x86_64")
+url="https://www.${pkgname%%-*}.com/support/software-defined-perimeter-support"
+license=("custom" "custom:commercial")
+depends=("dnsmasq" "gtk3" "libsecret" "libxss" "nodejs" "nss" "python-dbus")
+optdepends=("gnome-keyring: saves the endpoint certificate between sessions")
+provides=("${pkgname}")
+conflicts=()
+replaces=("${pkgname}-${pkgver%%.*}")
 options=(staticlibs)
+source=(
+  "https://bin.${pkgname}.com/${pkgver%.*}/client/${pkgname}_${pkgver}_amd64.deb"
+  "${pkgname}-${pkgname%%-*}driver.service.patch"
+)
+sha256sums=(
+  "3b52301d8e6c900f82d931f24f6ffdfcd0291662ed4bafe57e1deebdc321df40"
+  "0789aa07d6a7af44187e407696d930e78c50370c19b8399722ebecb0655ffcdb"
+)
 
 prepare() {
-    tar -xf data.tar.xz
+  mkdir "${srcdir}/${pkgname}"
+  cd "${srcdir}/${pkgname}"
+
+  bsdtar -xf "${srcdir}/data.tar.xz" -C .
+
+  patch -Np1 -i "${srcdir}/${pkgname}-${pkgname%%-*}driver.service.patch"
+
+  # Remove unnecessary .deb related directory
+  rm -rf "${srcdir}/${pkgname}/etc/init.d"
 }
 
 package() {
-    cp -dpr "${srcdir}"/{etc,lib,opt,usr} "${pkgdir}"
-    mv -v "$pkgdir/lib/systemd/system" "$pkgdir/usr/lib/systemd/"
-    rm -vrf "$pkgdir/lib"
-
-    cp -v "$srcdir/appgatedriver.service" "$pkgdir/usr/lib/systemd/system/appgatedriver.service"
-    patch "$pkgdir/opt/appgate/linux/nm.py" "$srcdir/nm.py.patch"
-    
-    mkdir -vp "$pkgdir/usr/share/licenses/appgate-sdp"
-    cp -v "$pkgdir/usr/share/doc/appgate/copyright" "$pkgdir/usr/share/licenses/appgate-sdp"
-    cp -v "$pkgdir/usr/share/doc/appgate/LICENSE.github" "$pkgdir/usr/share/licenses/appgate-sdp"
-    cp -v "$pkgdir/usr/share/doc/appgate/LICENSES.chromium.html.bz2" "$pkgdir/usr/share/licenses/appgate-sdp"
-}
+  # Install application files
+  cp -dpr "${srcdir}/${pkgname}/"{opt,usr,etc} "${pkgdir}"
 
-md5sums=('17101aac7623c06d5fbb95f50cf3dbdc'
-         '002644116e20b2d79fdb36b7677ab4cf'
-         'c36c11d995cc341f2f1eb4c3b6afa732')
+  # Install service files
+  install -dm755 "${pkgdir}/usr/lib/systemd/system"
+  install -Dm644 "${srcdir}/${pkgname}/lib/systemd/system/"* "${pkgdir}/usr/lib/systemd/system/"
+
+  # Install license files
+  install -Dm644 "${srcdir}/${pkgname}/usr/share/doc/${pkgname%%-*}/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
+  install -Dm644 "${srcdir}/${pkgname}/usr/share/doc/${pkgname%%-*}/LICENSE.github" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.github"
+  install -Dm644 "${srcdir}/${pkgname}/usr/share/doc/${pkgname%%-*}/LICENSES.chromium.html.bz2" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSES.chromium.html.bz2"
+}