c-list-git: new git package for c-list project

New package that builds the c-list project, which implements a
standalone circular double linked list in ISO C11.

Signed-off-by: David Herrmann <dh.herrmann@gmail.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8537fd19f6c5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: David Herrmann <dh.herrmann@gmail.com>
+
+_pkgorg=c-util
+_pkgname=c-list
+pkgdesc='Circular Double Linked List Implementation in Standard ISO-C11'
+pkgver=r13.208f4a2
+pkgrel=1
+
+pkgname=$_pkgname-git
+arch=('i686' 'x86_64')
+url="https://github.com/$_pkgorg/$_pkgname"
+license=('Apache')
+depends=('glibc')
+makedepends=('git' 'meson')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("$pkgname::git+https://github.com/$_pkgorg/$_pkgname")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  rm -Rf "build"
+  meson --prefix=/usr --buildtype=release "$pkgname" "build"
+  ninja -v -C "build"
+}
+
+check() {
+  ninja -v -C "build" test
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -v -C "build" install
+}