Adopted package & updated PKGBUILD.

Updated dependancies.
Forced use of system libraries in build.
Added check function.
Updated package function to only install necessary files.

1 files changed, 44 insertions, 19 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 7456f828052b..a0a0e6a195a4 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,31 +1,56 @@
+# Maintainer: Paul Hentschel (hpmachining)
+# Contributor: greyltc
+
 pkgname=cbang-git
-pkgver=1.0.1.r229.g3335df9
-pkgrel=3
-pkgdesc="a library of cross-platform C++ utilities"
-arch=('any')
-url="https://github.com/CauldronDevelopmentLLC/cbang.git"
-license=('GNU GPL v2.1')
-depends=('scons'
-	'chakracore-cauldron-git'
-	'boost-libs'
-	'openssl'
-	'libmariadbclient')
-source=("git+https://github.com/CauldronDevelopmentLLC/cbang")
-md5sums=('SKIP')
+pkgver=1.3.1.r5.g9ac7a2b
+pkgrel=1
+pkgdesc="A library of cross-platform C++ utilities"
+arch=('x86_64')
+url="https://github.com/CauldronDevelopmentLLC/cbang"
+license=('LGPL2.1')
+depends=(
+  'v8-3.14'
+  'libevent'
+  'sqlite'
+  're2'
+  'libyaml'
+  'zlib'
+  'bzip2'
+  'expat'
+  'mariadb-libs'
+)
+makedepends=(
+  'git'
+  'scons'
+)
+checkdepends=(
+  'python2'
+)
+conflicts=("${pkgname%-git}")
+provides=("${pkgname%-git}")
+source=("git+https://github.com/CauldronDevelopmentLLC/cbang.git")
+sha256sums=('SKIP')
 
 pkgver() {
-  cd cbang
+  cd "${pkgname%-git}"
   git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
 }
 
 build() {
-  cd cbang
-  export CHAKRA_CORE_HOME="/opt/chakracore-cauldron-git"
+  cd "${pkgname%-git}"
+  scons disable_local="libevent sqlite3 re2 libyaml zlib bzip2 expat"
+}
+
+check() {
+  cd "${pkgname%-git}/tests"
   scons
+  python2 ./testHarness
 }
 
 package() {
-  mkdir -p ${pkgdir}/opt
-  cp -a ${srcdir}/cbang "${pkgdir}/opt/${pkgname}"
+  cd "${pkgname%-git}"
+  scons install prefix="$pkgdir/opt/${pkgname%-git}"
+  install -m644 lib/libcbang-boost.a -t "$pkgdir/opt/${pkgname%-git}/lib" 
+  cp -a config/ "$pkgdir/opt/${pkgname%-git}/config/"
+  cp -a src/boost/boost/ "$pkgdir/opt/${pkgname%-git}/include/"
 }
-