Initial commit with the original PKGBUILD.

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bae480ef5820
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@gmail.com>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: dorphell <dorphell@archlinux.org>
+
+pkgname=enchant
+pkgver=1.6.1
+pkgrel=2
+pkgdesc="A wrapper library for generic spell checking"
+arch=('i686' 'x86_64')
+url="https://abiword.github.io/enchant/"
+license=('LGPL')
+depends=('aspell' 'hunspell' 'hspell' 'libvoikko' 'glib2')
+makedepends=('git')
+_commit=7c0ec265a89808893a692f6205f2555f30198444  # tags/enchant-1-6-1
+source=("git+https://github.com/AbiWord/enchant.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^enchant-//;s/-/\./g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+    --disable-static \
+    --disable-ispell \
+    --with-myspell-dir=/usr/share/myspell
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="${pkgdir}" install
+}