Add go-licenses-git.

1 files changed, 46 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c4d0da9c6a85
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Andrea Denisse Gómez <aur at denisse dot dev>
+
+pkgname=go-licenses-git
+_pkgname=${pkgname%-git}
+pkgdesc='Reports on the licenses used by a Go package and its dependencies.'
+arch=(aarch64 armv5h armv6h armv7h x86_64)
+url='https://github.com/google/go-licenses'
+_branch='master'
+pkgver=r37.ce1d916
+pkgrel=1
+license=('APACHE')
+makedepends=(git go)
+source=("$_pkgname::git+$url.git#branch=$_branch")
+sha256sums=('SKIP')
+provides=($_pkgname)
+conflicts=($_pkgname)
+
+pkgver() {
+  cd "$_pkgname"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+prepare() {
+  mkdir -p "${pkgname}/build"
+}
+
+build() {
+  cd $_pkgname
+
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+  go build -o build/ .
+}
+
+package() {
+  cd "$_pkgname"
+  install -Dm755 build/$_pkgname "$pkgdir"/usr/bin/$_pkgname
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+}