Initial commit

1 files changed, 45 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d600c24acdbb
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Daniel Mouritzen <dmrtzn at gmail dot com>
+
+_hkgname=blaze-svg
+pkgname=haskell-blaze-svg
+pkgver=0.3.6.1
+pkgrel=1
+pkgdesc="A blazingly fast SVG combinator library for Haskell"
+url="https://github.com/deepakjois/blaze-svg"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-markup' 'haskell-mtl')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha256sums=('f6a4f1bba1e973b336e94de73369f4562778fde43b6ac7c0b32d6a501527aa60')
+
+build() {
+  cd "$_hkgname-$pkgver"
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd "$_hkgname-$pkgver"
+  runhaskell Setup test
+}
+
+package() {
+  cd "$_hkgname-$pkgver"
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}