add hexxy

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8bef67c1df59
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: noraj <printf %s 'YWxleGFuZHJlLnphbm5pQGV1cm9wZS5jb20='|base64 -d>
+
+pkgname=hexxy-git
+_pkgname=hexxy
+pkgver=17.bc0cb46
+pkgrel=1
+pkgdesc='A modern and beautiful alternative to xxd and hexdump.'
+arch=('x86_64' 'aarch64')
+url='https://github.com/sweetbbak/hexxy'
+license=('custom:unknown')
+depends=()
+makedepends=('git' 'go')
+conflicts=('hexxy')
+source=("git+https://github.com/sweetbbak/$_pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+
+  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+build() {
+  cd $_pkgname
+
+  GOPATH="$srcdir" go mod download
+  GOPATH="$srcdir" go build \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-s -w" \
+    -o $_pkgname .
+}
+
+package() {
+  cd $_pkgname
+
+  install -Dm 755 $_pkgname "$pkgdir/usr/bin/$_pkgname"
+  install -Dm 644 -t "$pkgdir/usr/share/doc/$_pkgname/" README.md
+}
+