isoquery 3.2.7-1 update

Migrate to https://codeberg.org/toddy/isoquery, as upstream moved from
https://github.com/toddy15/isoquery.

Disable integration tests involving `de` and `fr` locales, as they do
not have to be installed on build systems.

1 files changed, 24 insertions, 13 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 57a314ff24c1..0a95d2a0f8fc 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,40 +1,51 @@
 # Maintainer: Nicolas Iooss <nicolas.iooss_aur at m4x.org>
 
 pkgname=isoquery
-pkgver=3.2.3
+pkgver=3.2.7
 pkgrel=1
 pkgdesc="Search and display ISO codes for countries, languages, currencies, and scripts."
 arch=('i686' 'x86_64')
-url="https://github.com/toddy15/isoquery"
+url="https://codeberg.org/toddy/isoquery"
 license=('GPL3')
 depends=('iso-codes' 'json-glib')
-makedepends=('gettext' 'po4a' 'python-docutils')
-source=("$pkgname-$pkgver.tar.gz::https://github.com/toddy15/$pkgname/archive/v$pkgver.tar.gz")
-sha256sums=('56b451904566b741bdea2632c9c45e595fc16b6a1e9b3859b313faee76eaa621')
+makedepends=('gettext' 'perl-syntax-keyword-try' 'po4a' 'python-docutils')
+source=("$pkgname-$pkgver.tar.gz::https://codeberg.org/toddy/$pkgname/archive/v$pkgver.tar.gz")
+sha256sums=('331d820bdf62a72e02464f94cdecf55049545549d617a2332bf84e9f550d6381')
 
 prepare() {
-    cd "$pkgname-$pkgver"
-
-    # Use en_US locale instead of C.UTF-8 to fix a test
-    # https://github.com/toddy15/isoquery/issues/3
-    sed -e 's/C\.UTF-8/en_US\.UTF-8/' -i tests/integration.c
+    cd "$pkgname"
+
+    # Some integration tests expect "de" or "fr" lang to be installed.
+    # Remove them.
+    # List obtained with: grep ' -l fr' -rl tests/expected
+    rm tests/expected/iso_15924/all_localized_test_commandline.txt
+    rm tests/expected/iso_3166-1/all_localized_test_commandline.txt
+    rm tests/expected/iso_3166-2/all_localized_test_commandline.txt
+    rm tests/expected/iso_3166-3/all_localized_test_commandline.txt
+    rm tests/expected/iso_4217/all_localized_test_commandline.txt
+    rm tests/expected/iso_639-2/all_localized_test_commandline.txt
+    rm tests/expected/iso_639-3/all_localized_test_commandline.txt
+    rm tests/expected/iso_639-5/all_localized_test_commandline.txt
+    # List obtained with: grep ' --locale de' -rl tests/expected
+    rm tests/expected/iso_3166-1/invalid_codes_localized_test_commandline.txt
+    rm tests/expected/iso_3166-1/multiple_codes_localized_test_commandline.txt
 }
 
 build() {
-    cd "$pkgname-$pkgver"
+    cd "$pkgname"
 
     ./configure --prefix=/usr
     make
 }
 
 check() {
-    cd "$pkgname-$pkgver"
+    cd "$pkgname"
 
     make check
 }
 
 package() {
-    cd "$pkgname-$pkgver"
+    cd "$pkgname"
 
     make DESTDIR="$pkgdir" install
 }