Patch -Werror=stringop-truncation build error

Update cmake build.
Update arch.
Remove ncurses dependency.
Change source URL from git:// to git+https://.
Minor edits.

1 files changed, 13 insertions, 16 deletions

diff --git a/PKGBUILD b/PKGBUILD
index a05d028ca0ec..9d9bd4b29b6e 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,33 +1,30 @@
 # Maintainer: willemw <willemw12@gmail.com>
 
-_pkgname=ngp
-pkgname=$_pkgname-git
-pkgver=1.3.r98.g25e0fe5
+pkgname=ngp-git
+pkgver=1.3.r201.gc15dc44
 pkgrel=1
 pkgdesc="Ncurses grep tool"
-arch=('i686' 'x86_64')
+arch=('x86_64')
 url="https://github.com/jonathanklee/ngp"
 license=('GPL')
-depends=('ncurses')
 makedepends=('cmake' 'git' 'libconfig')
-provides=($_pkgname)
-conflicts=($_pkgname)
-source=($pkgname::git://github.com/jonathanklee/ngp.git)
-md5sums=(SKIP)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+md5sums=('SKIP')
 
 pkgver() {
-  cd $pkgname
-  git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
+  git -C $pkgname describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
 }
 
 build() {
-  cd $pkgname
-  cmake -DCMAKE_INSTALL_PREFIX=/usr .
-  make
+  CFLAGS="$CFLAGS -Wno-error=stringop-truncation"
+
+  cmake -B build -S $pkgname -DCMAKE_BUILD_TYPE=None -DCMAKE_INSTALL_PREFIX=/usr -Wno-dev
+  make -C build
 }
 
 package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir/" install
+  make -C build DESTDIR="$pkgdir/" install
 }