Release Nuvola Spotify app

1 files changed, 33 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..12e51b6b9ff7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: Dhananjay Sathe <dhananjaysathe@gmail.com>
+# Contributor: Patrick Burroughs (Celti) <celti@celti.name>
+
+pkgname=nuvola-app-spotify-git
+pkgver=r17.548023a
+pkgrel=1
+pkgdesc="Spotify integration for Nuvola Player."
+arch=("any")
+url="https://github.com/tiliado/nuvola-app-spotify"
+license=('custom:BSD')
+depends=('nuvolaplayer-git')
+makedepends=('git')
+source=("${pkgname}::git+https://github.com/tiliado/nuvola-app-spotify.git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	( set -o pipefail
+		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+build() {
+	cd "$pkgname"
+	make build
+}
+
+package() {
+	cd "$pkgname"
+	install -vCDm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	make install DEST="${pkgdir}/usr/share/nuvolaplayer3/web_apps"
+}