Initial import

1 files changed, 61 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..30ee826edcfb
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,61 @@
+# Maintainer:  jyantis <yantis@yantis.net>
+
+pkgname=python-bottlenose-git
+pkgver=0.6.2.r113.bf4b02a
+pkgrel=2
+pkgdesc='A stable, up-to-date Python 3 wraper for the Amazon Product Advertising API'
+arch=('any')
+url='https://github.com/lionheart/bottlenose'
+license=('APACHE')
+depends=('python')
+source=('git+https://github.com/lionheart/bottlenose.git')
+sha256sums=('SKIP')
+makedepends=('git' 'python-setuptools')
+provides=('python-bottlenose')
+conflicts=('python-bottlenose')
+
+pkgver() {
+  cd bottlenose
+  set -o pipefail
+  _gitversion=$(printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)" )
+
+  # If there is a setup.py then pull the version tag from the file
+  if [ -f "setup.py" ]; then
+    if grep --quiet "version = " setup.py; then
+      printf "%s.%s" "$(grep -R "version = " setup.py | awk -F\' '{print $2}')" $_gitversion | sed 's/-/./g'
+    elif grep --quiet "version=" setup.py; then
+      printf "%s.%s" "$(grep -R "version=" setup.py | awk -F\' '{print $2}')" $_gitversion | sed 's/-/./g'
+    else
+      printf "%s" $_gitversion
+    fi
+  else
+    printf "%s" $_gitversion
+  fi
+}
+
+build() {
+  cd bottlenose
+  python setup.py build
+}
+
+check() {
+  cd bottlenose
+  python setup.py test --verbose
+}
+
+package() {
+  cd bottlenose
+
+  # We don't need anything related to git in the package
+  rm -rf .git*
+
+  python setup.py install --root="${pkgdir}" --optimize=1
+
+  # Install License
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+  # Install Documentation
+  install -D -m644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+}
+
+# vim:set ts=2 sw=2 et: