update to 0.1.36

1 files changed, 16 insertions, 34 deletions

diff --git a/PKGBUILD b/PKGBUILD
index d40c644debd5..4d38578b770a 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,48 +1,30 @@
 # Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
 # Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
 
-pkgbase=python-glad
-pkgname=(python-glad python2-glad)
-pkgver=0.1.34
-pkgrel=2
+pkgname=python-glad
+pkgver=0.1.36
+pkgrel=1
 pkgdesc='Multi-language GL/GLES/EGL/GLX/WGL loader-generator'
 arch=('any')
 url='https://github.com/Dav1dde/glad'
 license=('MIT' 'Apache')
-makedepends=('python-setuptools' 'python2-setuptools')
-source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
-sha256sums=('4be2900ff76ac71a2aab7a8be301eb4c0338491c7e205693435b09aad4969ecd')
-
-prepare() {
-	cp -a "glad-$pkgver" "glad-$pkgver-py2"
-}
+depends=('python')
+makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
+source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/g/glad/glad-$pkgver.tar.gz")
+sha256sums=('3fb00dbfec7ae6ddbeba04e21547f67f3ccfc795fc34562450cf3f2bb19fdbc7')
 
 build() {
-	pushd "glad-$pkgver"
-	python setup.py build
-	popd
-
-	pushd "glad-$pkgver-py2"
-	python2 setup.py build
-}
-
-package_python-glad() {
-	depends=('python3')
-
 	cd "glad-$pkgver"
-	export PYTHONHASHSEED=0
-	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
-	install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
-	install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+	python -m build --wheel --no-isolation
 }
 
-package_python2-glad() {
-	depends=('python2')
-	conflicts=('python-glad')
+package() {
+	cd "glad-$pkgver"
+	PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir/" dist/*.whl
 
-	cd "glad-$pkgver-py2"
-	export PYTHONHASHSEED=0
-	python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
-	install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
-	install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+	local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
+	install -d "$pkgdir/usr/share/licenses/$pkgname/"
+	ln -s \
+		"$_site/glad-$pkgver.dist-info/LICENSE" \
+		"$pkgdir/usr/share/licenses/$pkgname/"
 }