PKGBUILD: Use cmake and ninja for build

This commit changes PKGBUILD to use cmake and ninja for build. This also
fixes package warnings and errors.

Signed-off-by: Shohei Maruyama <cheat.sc.linux@outlook.com>

1 files changed, 17 insertions, 25 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 4a05619f0609..fc0eb9663d18 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,42 +1,34 @@
 # Maintainer: Shohei Maruyama <cheat.sc.linux@outlook.com>
 pkgname=tee-supplicant
 pkgver=3.19.0
-pkgrel=2
+pkgrel=3
 pkgdesc='Normal world client side of the TEE'
 arch=('x86_64' 'aarch64')
 url='https://github.com/OP-TEE/optee_client'
 license=('BSD')
-depends=()
+depends=('glibc' 'util-linux-libs')
+makedepends=('cmake' 'ninja')
 source=("git+https://github.com/OP-TEE/optee_client.git#tag=${pkgver}")
 sha256sums=('SKIP')
 
 build() {
-    cd ${srcdir}/optee_client/libteec
-    make ${MAKEFLAGS}
-
-    cd ${srcdir}/optee_client/tee-supplicant
-    make ${MAKEFLAGS}
+    cmake -B build -S optee_client -G Ninja \
+        -DCMAKE_INSTALL_PREFIX='/usr' \
+        -DCMAKE_BUILD_TYPE='None' \
+        -DCFG_TEE_CLIENT_LOG_FILE='/var/log/tee/teec.log' \
+        -DBUILD_SHARED_LIBS=ON
+    cmake --build build
 }
 
 package() {
-    # install library
-    install -dm755 ${pkgdir}/usr/lib/
-
-    cd ${pkgdir}/usr/lib/
-    install -m755 ${srcdir}/optee_client/out/libteec/libteec.so.1.0.0 .
-    ln -s libteec.so.1.0.0 libteec.so
-    ln -s libteec.so.1.0.0 libteec.so.1
-    ln -s libteec.so.1.0.0 libteec.so.1.0
-
-    # install c headers
-    install -dm755 ${pkgdir}/usr/include
+    DESTDIR=${pkgdir} cmake --install build
 
-    cd ${pkgdir}/usr/include
-    for i in ${srcdir}/optee_client/public/*.h; do
-        install -m644 ${i} .
-    done
-
-    # install tee-supplicant
+    # mv tee-supplicant into /usr/bin
     install -dm755 ${pkgdir}/usr/bin
-    install -m755 ${srcdir}/optee_client/out/tee-supplicant/tee-supplicant ${pkgdir}/usr/bin
+    mv ${pkgdir}/usr/sbin/tee-supplicant ${pkgdir}/usr/bin
+    rm -rf ${pkgdir}/usr/sbin
+
+    # install license
+    install -dm755 ${pkgdir}/usr/share/licenses/${pkgname}
+    install -m644 optee_client/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/
 }