initial commit

1 files changed, 45 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..86d195551ef4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-julia-git
+pkgver=0.19.0.r1.g12ea597
+pkgrel=1
+pkgdesc="Julia grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/tree-sitter/tree-sitter-julia"
+license=('MIT')
+groups=('tree-sitter-grammars')
+depends=('glibc')
+makedepends=('git' 'tree-sitter' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	( set -o pipefail
+	  git describe --long --tags 2>/dev/null | sed 's/^v//;s/-/.r/;s/-/./' ||
+	  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+prepare() {
+	cd "$pkgname"
+	tree-sitter generate
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c scanner.c
+	cc $LDFLAGS -shared parser.o scanner.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-julia.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-julia.so" "$pkgdir/usr/share/nvim/runtime/parser/julia.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}
+