xcb-util-cursor-git: fix license dir, pkgver(), provides, submodule

1 files changed, 27 insertions, 31 deletions

diff --git a/PKGBUILD b/PKGBUILD
index d6045d9d596c..796b47b18440 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,49 +1,45 @@
-# Maintainer: Dan Beste <dan.ray.beste@gmail.com>
+# Maintainer: éclairevoyant
+# Contributor: Dan Beste <dan dot ray dot beste at gmail dot com>
 
-pkgname='xcb-util-cursor-git'
-pkgver=0.1.3.r1.g947eaba
+_pkgname='xcb-util-cursor'
+pkgname="$_pkgname-git"
+pkgver=0.1.4.r3.103bcca
 pkgrel=1
 pkgdesc='XCB cursor library'
-arch=('x86_64')
+arch=(x86_64)
 url='https://xcb.freedesktop.org/'
-license=('MIT')
-depends=('libxcb' 'xcb-util-renderutil' 'xcb-util-image')
-makedepends=('git' 'xorg-util-macros' 'gperf')
-provides=("${pkgname/-git/}")
-conflicts=("${pkgname/-git/}")
-source=(
- 'git+https://anongit.freedesktop.org/git/xcb/util-cursor.git'
- 'git+https://anongit.freedesktop.org/git/xcb/util-common-m4.git'
-)
-sha256sums=('SKIP' 'SKIP')
+license=(MIT)
+depends=(libxcb xcb-util-image xcb-util-renderutil)
+makedepends=(git gperf xorg-util-macros)
+provides=("$_pkgname=${pkgver%%.r*}")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+https://anongit.freedesktop.org/git/xcb/util-cursor.git"
+        'git+https://anongit.freedesktop.org/git/xcb/util-common-m4.git')
+b2sums=('SKIP'
+        'SKIP')
 
 pkgver() {
-  cd util-cursor
-
-  git describe --long --tags \
-    | sed 's/-/.r/;s/-/./'
+	git -C $_pkgname describe --long --tags | sed 's/^xcb-util-cursor-//;s/\([^-]*-\)g/r\1/;s/-/./g'
 }
 
 prepare() {
-  cd util-cursor
+	cd $_pkgname
 
-  git submodule init "m4"
-  git config "submodule.m4.url" "../util-common-m4"
-  git submodule update "m4"
+	git submodule init
+	git config submodule.m4.url "$srcdir/util-common-m4"
+	git -c protocol.file.allow=always submodule update
 }
 
 build() {
-  cd util-cursor
+	cd $_pkgname
 
-  ./autogen.sh --prefix=/usr
-  make
+	./autogen.sh --prefix=/usr
+	make
 }
 
 package() {
-  cd util-cursor
-  
-  DESTDIR="${pkgdir}" make install
-  install -Dm 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-}
+	cd $_pkgname
 
-# vim: ts=2 sw=2 et:
+	DESTDIR="$pkgdir" make install
+	install -vDm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}