1 files changed, 45 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b1b04be1e518
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
+# Contributor: kpcyrd <kpcyrd[at]archlinux[dot]org>
+# Contributor: Christian Hesse <eworm@archlinux.org>
+
+_android_arch=riscv64
+
+pkgname=android-${_android_arch}-libnghttp3
+pkgver=1.8.0
+pkgrel=1
+arch=('any')
+pkgdesc="HTTP/3 library written in C (Android ${_android_arch})"
+url='https://github.com/ngtcp2/nghttp3'
+license=('MIT')
+groups=('android-libnghttp3')
+depends=('android-ndk')
+makedepends=('android-cmake')
+options=(!strip !buildflags staticlibs !emptydirs)
+source=("https://github.com/ngtcp2/nghttp3/releases/download/v${pkgver}/nghttp3-${pkgver}.tar.xz")
+md5sums=('febaa2d6d1bf9105a4804df2db29becc')
+
+prepare() {
+    cd "${srcdir}/nghttp3-${pkgver}"
+    source android-env ${_android_arch}
+
+    autoreconf -i
+}
+
+build() {
+    cd "${srcdir}/nghttp3-${pkgver}"
+    source android-env ${_android_arch}
+
+    android-${_android_arch}-configure \
+        --enable-lib-only
+    make $MAKEFLAGS
+}
+
+package() {
+    cd "${srcdir}/nghttp3-${pkgver}"
+    source android-env ${_android_arch}
+
+    make DESTDIR="${pkgdir}" install
+    rm -rf "${pkgdir}/${ANDROID_PREFIX_SHARE}"
+    ${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
+    ${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a
+}