1 files changed, 27 insertions, 58 deletions
diff --git a/PKGBUILD b/PKGBUILD
index 6c5558718b2b..0c7f6e23d86f 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,66 +1,35 @@
-# $Id$
-# Maintainer: vri <t.j.a.devries(at)gmail(dot)com>
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor: vri <t.j.a.devries(at)gmail(dot)com>
 # Contributor: Nathan Owe <ndowens.aur at gmail dot com>
 
-# for customization
-_pkgname=cpp-netlib
-_ext=
-_basedir=/usr
-_boost=boost${_ext}
-
-pkgname=${_pkgname}${_ext}
-pkgver=0.12.0
-pkgrel=2
-pkgdesc="A library that provides application layer protocol support using modern C++ techniques"
-arch=('i686' 'x86_64')
-url="http://cpp-netlib.github.com/"
-license=('custom')
-depends=()
-optdepends=('openssl: for https')
-makedepends=('cmake>=2.8.10' 'boost' 'boost-libs' 'asio')
-#options=(staticlibs)
-source=(
-         http://downloads.cpp-netlib.org/$pkgver/$_pkgname-$pkgver-final.tar.gz
-         OPENSSL_NO_SSL3.patch
-         )
-sha256sums=(
-         'a0a4a5cbb57742464b04268c25b80cc1fc91de8039f7710884bf8d3c060bd711'
-         'e7b4b7ecdafb51211d9be65fd179e8cd7cea71480aaeb4f30f11d5c8fc251f03'
-         )
-
-prepare() {
-        cd "$pkgname-$pkgver-final"
-        patch -Np0 -i "$srcdir/OPENSSL_NO_SSL3.patch"
-}
+pkgname=cpp-netlib
+pkgver=0.13.0
+pkgrel=1
+pkgdesc='Cross-platform, standards compliant networking library'
+arch=('x86_64')
+url='https://github.com/cpp-netlib/cpp-netlib'
+license=('custom:BSL')
+depends=('gcc-libs' 'openssl')
+makedepends=('boost' 'cmake')
+provides=("libcppnetlib-client-connections.so=$pkgver" "libcppnetlib-uri-server-parsers.so=$pkgver" "libcppnetlib-uri.so=$pkgver")
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgname-$pkgver-final.tar.gz")
+sha256sums=('897259d9f9087acba33911aec925804e6236a7a77f5444dedde6145049605a34')
 
 build() {
-  install -d $srcdir/build
-  cd $srcdir/build
-  # use asio from system
-  sed -i -e "s|include_directories(deps/asio/asio/include)||g" $srcdir/$_pkgname-$pkgver-final/CMakeLists.txt
-  cmake -DBOOST_ROOT=$_basedir -DCPP-NETLIB_BUILD_TESTS=OFF -DCPP-NETLIB_BUILD_EXAMPLES=OFF -DCPP-NETLIB_BUILD_SHARED_LIBS=ON -DCMAKE_INSTALL_PREFIX:PATH=${pkgdir}${_basedir} ../"$_pkgname-$pkgver-final"
-#  cmake -DBOOST_ROOT=$_basedir -DCPP-NETLIB_BUILD_TESTS=ON -DCPP-NETLIB_BUILD_EXAMPLES=ON -DCPP-NETLIB_BUILD_SHARED_LIBS=ON -DCMAKE_INSTALL_PREFIX:PATH=${pkgdir}${_basedir} ../"$_pkgname-$pkgver-final"
-  make
-#  make test
+	cmake \
+		-B build \
+		-S "$pkgname-$pkgname-$pkgver-final" \
+		-DCPP-NETLIB_BUILD_SHARED_LIBS=ON \
+		-DCPP-NETLIB_BUILD_TESTS=OFF \
+		-DCPP-NETLIB_BUILD_EXAMPLES=OFF \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DBOOST_DIR=/usr \
+		-Wno-dev
+	cmake --build build
 }
 
 package() {
-  cd $srcdir/build
-  make install
-
-  install -d ${pkgdir}${_basedir}/lib
-  if test "$CARCH" == x86_64; then
-    mv ${pkgdir}${_basedir}/lib64/* ${pkgdir}${_basedir}/lib
-    rmdir ${pkgdir}${_basedir}/lib64
-  fi
-  for _file in $(find ${pkgdir}${_basedir}/lib/cmake/cppnetlib -type f -name "*.cmake");
-  do
-    sed -i -e "s|${pkgdir}${_basedir}/lib64|${_basedir}/lib|g" $_file
-    sed -i -e "s|${pkgdir}${_basedir}|${_basedir}|g" $_file
-  done
-
-  #Install license
-  install -d ${pkgdir}/usr/share/licenses/$pkgname
-  cd "$srcdir/$_pkgname-$pkgver-final"
-  install -Dm644 LICENSE_1_0.txt ${pkgdir}/usr/share/licenses/$pkgname/LICENSE_1_0.txt
+	DESTDIR="$pkgdir" cmake --install build
+	cd "$pkgname-$pkgname-$pkgver-final"
+	install -Dvm644 LICENSE_1_0.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
 }