1 files changed, 60 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..46f5c70cf179
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,60 @@
+pkgname=i3-gaps-cameronleger-git
+pkgver=4.15.0.1.r607.gaddf48ed
+pkgrel=1
+pkgdesc='A fork of i3-gaps with issue #22 fix (outer gaps cause weird tiling)'
+arch=('i686' 'x86_64')
+url='https://github.com/cameronleger/i3'
+license=('BSD')
+provides=('i3-wm')
+conflicts=('i3-wm' 'i3bar' 'i3bar-git' 'i3-git' 'i3-gaps-git' 'i3-gaps')
+groups=('i3-vcs')
+depends=('xcb-util-keysyms' 'xcb-util-wm' 'libev' 'yajl'
+         'startup-notification' 'pango' 'perl' 'xcb-util-cursor' 'xcb-util-xrm'
+         'libxkbcommon-x11')
+makedepends=('git' 'asciidoc' 'docbook-xsl' 'xmlto' 'perl' 'pkgconfig')
+optdepends=('rxvt-unicode: The terminal emulator used in the default config.'
+            'dmenu: As menu.'
+            'i3lock: For locking your screen.'
+            'i3status: To display system information with a bar.'
+            'perl-json-xs: For i3-save-tree'
+            'perl-anyevent-i3: For i3-save-tree')
+options=('docs' '!strip')
+source=('git://github.com/cameronleger/i3#branch=fix-22')
+sha1sums=('SKIP')
+
+_gitname='i3'
+
+pkgver() {
+  cd "$srcdir/$_gitname"
+  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "$_gitname"
+
+  autoreconf --force --install
+
+  rm -rf build/
+  mkdir -p build && cd build/
+
+  ../configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --disable-sanitizers
+
+  # See https://lists.archlinux.org/pipermail/arch-dev-public/2013-April/024776.html
+  make CPPFLAGS+="-U_FORTIFY_SOURCE"
+}
+
+package() {
+  cd "$_gitname"
+  cd build/
+
+  make DESTDIR="$pkgdir/" install
+
+  install -Dm644 ../LICENSE \
+    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et:
+