1 files changed, 45 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..cef96533dfd9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+pkgname=openmodelica-dev-omc
+pkgver=1.13.0
+pkgrel=1
+
+pkgdesc="The Open Source Modelica Suite - OpenModelica Compiler"
+arch=('i686' 'x86_64')
+url="https://openmodelica.org"
+license=('OSMC-PL')
+groups=(openmodelica-dev)
+
+_group=OpenModelica
+_name=OMCompiler
+_tag=v${pkgver}-dev
+
+depends=('java-environment' 'lpsolve' 'hdf5-openmpi' 'omniorb' 'openscenegraph' 'sundials' 'libatomic_ops' 'python' 'gtkglext' 'ruby' 'coin-or-ipopt' 'qjson' 'suitesparse' 'boost-libs')
+
+makedepends=('gcc-fortran' 'boost' 'clang' 'cmake' 'java-environment' 'antlr2' 'git' 'expat' 'ncurses' 'readline' 'opencl-headers' 'imagemagick')
+
+provides=('openmodelica-omc')
+conflicts=('openmodelica' 'openmodelica-omc' 'openmodelica-git')
+
+source=(  "git+https://github.com/${_group}/${_name}.git#tag=${_tag}")
+sha1sums=('SKIP')
+
+prepare() {
+  cd "$srcdir/$_name"
+  git checkout "tags/${_tag}"
+  sed -i "s,../,https://github.com/${_group}/,g" .gitmodules
+  git submodule sync
+  git submodule update --init --recursive
+}
+
+build() {
+  cd "$srcdir/$_name"
+  autoconf
+  export CPPFLAGS="$CPPFLAGS -DH5_USE_18_API"
+  ./configure --prefix=/usr/ --without-omc --with-omniORB  --with-cppruntime --with-lapack='-llapack -lblas'
+  make
+}
+
+package() {
+  cd "$srcdir/$_name/build"
+  mkdir -p ${pkgdir}/usr
+  cp -r * ${pkgdir}/usr
+}