1 files changed, 51 insertions, 14 deletions
diff --git a/PKGBUILD b/PKGBUILD
index 180be0acfb24..8eb6abda9ce6 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,30 +1,67 @@
 # Maintainer: Robin Appelman <robin@icewind.nl> 
 
-pkgname=php-smbclient
+_upstream=libsmbclient-php
+pkgbase=php-smbclient
+pkgname=(php-smbclient php-legacy-smbclient)
 _extname=smbclient
-pkgver=1.0.6
-pkgrel=2
+pkgver=1.1.1
+pkgrel=1
 pkgdesc="PHP bindings for libsmbclient."
 arch=('i686' 'x86_64' 'armv7h')
 url="https://github.com/eduardok/libsmbclient-php"
 license=('BSD')
-depends=('php' 'smbclient')
-backup=("etc/php/conf.d/${_extname}.ini")
+makedepends=('php' 'php-legacy')
+depends=('smbclient')
 source=("https://github.com/eduardok/libsmbclient-php/archive/${pkgver}.tar.gz")
-md5sums=('dd00ec1431149a7e627b62d659fc4ad8')
+b2sums=('8152ed3c92bdbbcdac59c19f77b203cb2fbaf98767d8137d3bbbc96906bb52c3bbdfacdfb5c32eecc4ccb6e44c9417b8c57e80621bd6e4d15a324f97f461984c')
+
+prepare() {
+  mv "${_upstream}-${pkgver}" "$pkgbase-$pkgver"
+  echo ";extension=smbclient.so" > "$pkgbase-$pkgver/${_extname}.ini"
+
+  cp -a "$pkgbase-$pkgver" "${pkgname[1]}-$pkgver"
+
+  (
+    cd "$pkgbase-$pkgver"
+    phpize
+  )
+
+  (
+    cd "${pkgname[1]}-$pkgver"
+    phpize-legacy
+  )
+}
 
 build() {
-  cd "libsmbclient-php-${pkgver}"
+  (
+    cd "$pkgbase-$pkgver"
+    ./configure --prefix=/usr
+    make
+  )
+
+  (
+    cd "${pkgname[1]}-$pkgver"
+    ./configure --prefix=/usr
+    make
+  )
+}
+
+package_php-legacy-smbclient() {
+  backup=("etc/php-legacy/conf.d/${_extname}.ini")
+
+  cd "${pkgname[1]}-$pkgver"
 
-  phpize
-  ./configure --prefix=/usr
-  make
+  make INSTALL_ROOT="${pkgdir}" install
+  install -vDm 644 "${_extname}.ini" -t "${pkgdir}/etc/php-legacy/conf.d/"
 }
 
-package() {
-  cd "libsmbclient-php-${pkgver}"
+package_php-smbclient() {
+  backup=("etc/php/conf.d/${_extname}.ini")
+
+  cd "$pkgbase-$pkgver"
 
   make INSTALL_ROOT="${pkgdir}" install
-  echo "extension=smbclient.so" > "${_extname}.ini"
-  install -D -m644 "${_extname}.ini" "${pkgdir}/etc/php/conf.d/${_extname}.ini"
+  install -vDm 644 "${_extname}.ini" -t "${pkgdir}/etc/php/conf.d/"
 }
+
+# vim:set ts=2 sw=2 et: