1 files changed, 40 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..22416b808b64
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Astro Benzene <universebenzene at sina dot com>
+
+pkgbase=python-aesara-theano-fallback
+_pname=${pkgbase#python-}
+_pyname=${_pname//-/_}
+pkgname=("python-${_pname}")
+pkgver=0.1.0
+pkgrel=1
+pkgdesc="Striving towards backwards compatibility with the Theano -> Aesara transition"
+arch=('any')
+url="https://github.com/exoplanet-dev/aesara-theano-fallback"
+license=('MIT')
+makedepends=('python-setuptools-scm'
+             'python-wheel'
+             'python-build'
+             'python-installer')
+checkdepends=('python-pytest' 'python-pymc3' 'python-pymc')
+source=("https://files.pythonhosted.org/packages/source/${_pyname:0:1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
+md5sums=('eb7eb529250399b36a2abae2a540039f')
+
+build() {
+    cd ${srcdir}/${_pyname}-${pkgver}
+
+    python -m build --wheel --no-isolation
+}
+
+check() {
+    cd ${srcdir}/${_pyname}-${pkgver}
+
+    PYTHONPATH="build/lib" pytest || warning "Tests failed"
+}
+
+package() {
+    depends=('python')
+    cd ${srcdir}/${_pyname}-${pkgver}
+
+    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
+    install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+    python -m installer --destdir="${pkgdir}" dist/*.whl
+}