blob: 66abd6a7365e619dd58dc53a984c7273c9cab2f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
_pkgname=3dslicer
pkgname=3dslicer-git
_pkgver=5.1.0
pkgver=5.1.0.r27906.0f29c7c9a7
pkgrel=1
pkgdesc='A free, open source and multi-platform software package widely used for medical, biomedical, and related imaging research'
arch=('x86_64')
url='https://www.slicer.org'
license=('BSD')
depends=(
bzip2
curl
dcmtk
libarchive
libffi
libxt
openssl
qt5-base
qt5-multimedia
qt5-script
qt5-svg
qt5-tools
qt5-webengine
qt5-x11extras
qt5-xmlpatterns
rapidjson
sqlite
teem
)
makedepends=(
cmake
gendesk
git
subversion
)
options=(!emptydirs !strip)
provides=(3dslicer=${pkgver})
conflicts=(3dslicer)
source=("${_pkgname}::git+https://github.com/Slicer/Slicer.git"
"${_pkgname}.svg::https://www.slicer.org/assets/img/3D-Slicer-Mark.svg"
)
sha512sums=('SKIP'
'3422d244f819a7ec4c475d3d8a90c79fcb73738920c0830b100c6342ca24d5be607ba60ee3d91892402036a0adf31d5ab7c8fc83f451121a7b537f7de5306014')
pkgver() {
cd "${srcdir}/${_pkgname}"
ver=$(printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)")
echo "${_pkgver}.${ver}"
}
prepare() {
echo "Creating desktop file"
gendesk -f -n --pkgname ${_pkgname} \
--categories "Graphics;MedicalSoftware;Science;" \
--exec "Slicer" \
--icon "${_pkgname}" \
--pkgdesc "${pkgdesc}"
# find sqlite with cmake's FindSQLite3
sed -i 's/find_package(${proj} REQUIRED)/find_package(SQLite3 REQUIRED)/' "${srcdir}/${_pkgname}/SuperBuild/External_sqlite.cmake"
# fix issue https://github.com/Slicer/Slicer/issues/6437
sed -i "s,list(APPEND Slicer_REQUIRED_QT_MODULES Script),list(APPEND Slicer_REQUIRED_QT_MODULES Script Test)," "${srcdir}/${_pkgname}/CMakeLists.txt"
}
build() {
cmake -B build -S "${srcdir}/${_pkgname}" \
-DBUILD_TESTING=OFF \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSlicer_BUILD_DOCUMENTATION=OFF \
-DSlicer_BUILD_I18N_SUPPORT=ON \
-DSlicer_STORE_SETTINGS_IN_APPLICATION_HOME_DIR=OFF \
-DSlicer_USE_GIT_PROTOCOL=OFF \
-DSlicer_USE_SYSTEM_CTK=OFF \
-DSlicer_USE_SYSTEM_CTKAPPLAUNCHER=OFF \
-DSlicer_USE_SYSTEM_CTKAppLauncherLib=OFF \
-DSlicer_USE_SYSTEM_CTKResEdit=OFF \
-DSlicer_USE_SYSTEM_DCMTK=ON \
-DSlicer_USE_SYSTEM_ITK=OFF \
-DSlicer_USE_SYSTEM_JsonCpp=OFF \
-DSlicer_USE_SYSTEM_LZMA=ON \
-DSlicer_USE_SYSTEM_LibArchive=ON \
-DSlicer_USE_SYSTEM_LibFFI=ON \
-DSlicer_USE_SYSTEM_OpenSSL=ON \
-DSlicer_USE_SYSTEM_PCRE=OFF \
-DSlicer_USE_SYSTEM_ParameterSerializer=OFF \
-DSlicer_USE_SYSTEM_QT=ON \
-DSlicer_USE_SYSTEM_RapidJSON=ON \
-DSlicer_USE_SYSTEM_SimpleITK=OFF \
-DSlicer_USE_SYSTEM_SlicerExecutionModel=OFF \
-DSlicer_USE_SYSTEM_Swig=OFF \
-DSlicer_USE_SYSTEM_VTK=OFF \
-DSlicer_USE_SYSTEM_bzip2=ON \
-DSlicer_USE_SYSTEM_curl=ON \
-DSlicer_USE_SYSTEM_qRestAPI=OFF \
-DSlicer_USE_SYSTEM_sqlite=ON \
-DSlicer_USE_SYSTEM_tbb=OFF \
-DSlicer_USE_SYSTEM_teem=ON \
-DSlicer_USE_SYSTEM_zlib=ON \
-DSlicer_USE_SimpleITK=ON \
-DSlicer_USE_SimpleITK_SHARED=ON
make -C "build"
}
package() {
make -C "${srcdir}/build/Slicer-build" package
install -d "${pkgdir}/opt/${_pkgname}" "${pkgdir}/usr/bin"
tar xvf "${srcdir}/build/Slicer-build/"*.tar.gz -C "${pkgdir}/opt/${_pkgname}" --strip-components 1
ln -s /opt/${_pkgname}/Slicer "${pkgdir}/usr/bin"
install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -Dm644 "${srcdir}/${_pkgname}.svg" "${pkgdir}/usr/share/pixmaps/${_pkgname}.svg"
}
# vim:set ts=2 sw=2 et:
|