PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

# Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
# Contributor: Ionut Biru <ibiru@archlinux.org>

# vercheck-pkgbuild: auto
# vercheck-ubuntu: name=${pkgname%-*}, repo=utopic
# vercheck-archlinux: name=${pkgname%-*}, repo=extra, arch=x86_64
# vercheck#freedesktop: name=${pkgname%-*}, majorver=3.14
# vercheck#ppa: name=${pkgname%-*}, url=ppa:gnome3-team/gnome3-staging

pkgname=accountsservice-ubuntu
_ubuntu_rel=1ubuntu9
_ubuntu_ver=0.6.37
pkgver=0.6.40
pkgrel=1
pkgdesc="D-Bus interface for user account query and manipulation"
arch=(i686 x86_64)
url="http://cgit.freedesktop.org/accountsservice/"
license=(GPL3)
depends=(glib2 polkit systemd lightdm-ubuntu)
makedepends=(intltool gobject-introspection python2 vala)
provides=("accountsservice=${pkgver}")
conflicts=(accountsservice)
source=("http://cgit.freedesktop.org/accountsservice/snapshot/accountsservice-${pkgver}.tar.xz"
        "https://launchpad.net/ubuntu/+archive/primary/+files/accountsservice_${_ubuntu_ver:-${pkgver}}-${_ubuntu_rel}.debian.tar.xz"
        0001-Support-setting-reading-LightDM-autologin-setings.patch)
sha512sums=('41cd507c5a451cc88b8e6b28725c103ccd1d5819a60fdcea9e201a248ab609c5fe26ddc1eaebe6781425094cc073fb32485041ade83c433d4add952e172ae189'
            'b6c51ec1ca513100f109629ddd0c2b6575e5cba8f5ef5c39399ae8bc8a53078a22b522747cd659ed96de217555fbda5238de06f698c6d94a530eacd2b807a615'
            '0ba299e57a1629993f19bbc07178262bd07040f64e61df78c7b16596956be8037c6aff087505ece9d2f65c1bc66c8628ab09bcdb6ba9e2e4b2a6e937dd6cb2df')

prepare() {
  cd "accountsservice-${pkgver}"

  #patch -p1 -i ../0001-Support-setting-reading-LightDM-autologin-setings.patch

  # Apply Ubuntu patches
    # Disable patches
    sed -i \
      `# We have refreshed versions` \
        -e '/0007-add-lightdm-support.patch/d' \
      `# Arch Linux uses wheel group for system administration` \
        -e '/0002-create-and-manage-groups-like-on-a-ubuntu-system.patch/d' \
      `# adduser is Debian-specific` \
        -e '/0006-adduser_instead_of_useradd.patch/d' \
      `# Language patches are still pretty specific to Ubuntu, though` \
      `# Ubuntu is trying to get them merged upstream` \
        -e '/0001-formats-locale-property.patch/d' \
        -e '/0009-language-tools.patch/d' \
        -e '/0010-set-language.patch/d' \
        -e '/0012-add-keyboard-layout-support.patch/d' \
      `# Ubuntu-specific` \
        -e '/0021-support-extrausers.patch/d' \
        -e '/0016-add-input-sources-support.patch/d' \
      `# We do not need a pin-based authentication method` \
        -e '/0014-pam-pin.patch/d' \
        -e '/0015-pam-pin-ubuntu.patch/d' \
      `# Applied upstream` \
        -e '/0022-fix-desktop-centric-polkit-policy.patch/d' \
      `# Does not apply cleanly` \
        -e '/0013-add-has-message-support.patch/d' \
        ../debian/patches/series

  for i in $(grep -v '#' ../debian/patches/series); do
    msg "Applying ${i} ..."
    patch -p1 -i "../debian/patches/${i}"
  done
}

build() {
  cd "accountsservice-${pkgver}"

  ./autogen.sh \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib/accountsservice \
    --with-systemdsystemunitdir=/usr/lib/systemd/system \
    --localstatedir=/var \
    --disable-static \
    --enable-systemd

  make
}

package() {
  cd "accountsservice-${pkgver}"

  make DESTDIR="${pkgdir}" install
}