PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Victor Homic <aur (at) dothomic (dot) de>
# Contributor: Iyán Méndez Veiga <me (at) iyanmv (dot) com>
# Contributor: Aniket Pradhan <aniket17133 (at) iiitd (dot) ac (dot) in>
# Contributor: Martin Briza <m (at) rtinbriza (dot) cz>

pkgname=('adwaita-qt' 'adwaita-qt6')
pkgbase=adwaita-qt
pkgver=1.4.0+10+gd535207
pkgrel=1
pkgdesc="A style to bend Qt applications to look like they belong into GNOME Shell"
arch=('x86_64' 'aarch64')
url="https://github.com/FedoraQt/adwaita-qt"
license=('GPL')
depends=('qt5-x11extras' 'qt6-base')
makedepends=('cmake' 'git' 'sassc')
_commit=d535207a5fe587e2bb862388398ea7636888e702
source=("git+https://github.com/FedoraQt/adwaita-qt.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgbase"
  git describe --tags | sed 's/-/+/g'
}

build() {
  cmake -B build-qt5 -S "$pkgbase" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_QT6=OFF \
    -Wno-dev
  make -C build-qt5

  cmake -B build-qt6 -S "$pkgbase" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_QT6=ON \
    -Wno-dev
  make -C build-qt6
}

package_adwaita-qt() {
  pkgdesc="A style to bend Qt5 applications to look like they belong into GNOME Shell"
  depends=('qt5-x11extras')
  provides=('libadwaitaqtpriv.so=1' 'libadwaitaqt.so=1')

  make -C build-qt5 DESTDIR="$pkgdir" install
}

package_adwaita-qt6() {
  pkgdesc="A style to bend Qt6 applications to look like they belong into GNOME Shell"
  depends=('libxcb' 'qt6-base')
  provides=('libadwaitaqt6priv.so=1' 'libadwaitaqt6.so=1')

  make -C build-qt6 DESTDIR="$pkgdir" install
}