blob: a071b81f3003df45fa76c52b816aeb2e7d8691b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=aio-creator-neo
pkgver=3.1.3
pkgrel=1
pkgdesc='Design a custom app to control your smart home. Supports many vendors.'
arch=('x86_64')
url='https://www.mediola.com/en/products#aio-creator-neo'
license=('LicenseRef-eula')
depends=('bash' 'dxvk' 'wine' 'wine-mono' 'wine-gecko')
makedepends=('innoextract')
options=('!debug' '!strip')
install="${pkgname}.install"
# The vendor’s EULA is available online. To update it, run:
# curl -L 'https://www.mediola.com/eula' | html2text --body-width=80 | awk '/^###\s.*(EULA)/,/^####$/ { print }' | head -n -2 > eula.md
_pkgver_major_minor="$(cut -d . -f -2 <<< "${pkgver}")"
source=(
"${pkgname}-${pkgver}-installer.exe::https://s3-eu-west-1.amazonaws.com/mediola-download/creator_neo/release/${_pkgver_major_minor}/${pkgver}/aioCreatorNeoInstaller.exe"
"${pkgname}.bash"
'eula.md'
)
sha512sums=(
'640ed3812a9103e8cee5fa8a4cd02d642b3907d63efebcb27fb2127d0063c3382363d3a511a2f971bc6d310939aa141d614d7786053505aec449380526b7b088'
'308b84b654e63fe14cd68f6bb8fdeb1f0e7afe1b15127fa5779cbe40227c9a6616060b27e28e98505f72d26873379b6a3672fc98060f6e47e64667f81a91d500'
'70910fb6b981c832416396474b8e0a551457cf64a433626eb80785e862aa999719151d022d538c66b9a5fa2c5ec7bd3506289a614c1c1f10cfabba022993ab77'
)
prepare() {
innoextract -d "${srcdir}" "${pkgname}-${pkgver}-installer.exe"
}
package() {
echo >&2 'Packaging credits.html'
install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
"${srcdir}/app/aio_creator_neo/credits.html"
echo >&2 'Packaging license files'
install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
'eula.md' \
"${srcdir}/app/aio_creator_neo/licenses/files"/*
echo >&2 'Packaging the executable'
install -D -m 755 -T "${srcdir}/aio-creator-neo.bash" \
"${pkgdir}/usr/bin/aio-creator-neo"
echo >&2 'Packaging app files'
mkdir -p "${pkgdir}/opt/${pkgname}"
cp -r --preserve=mode "${srcdir}/app" "${srcdir}/commonappdata" \
"${pkgdir}/opt/${pkgname}/"
}
|