blob: 9b92bffa678e7c77d105aba76bf9f7b5f706b350 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
pkgname=algernon
pkgver=1.15.1
pkgrel=1
pkgdesc='Web server with Lua, Markdown, QUIC, Redis and PostgreSQL support'
arch=(x86_64)
url='https://algernon.roboticoverlords.org/'
license=(BSD)
makedepends=(go)
optdepends=('mariadb: For using the MariaDB/MySQL database backend'
'postgresql: For using the PostgreSQL database backend'
'redis: For using the Redis database backend')
source=("git+https://github.com/xyproto/algernon#commit=a759b348260c3bdc9108d73847d7d03b8f6ca2d5") # tag: v1.15.1
b2sums=(SKIP)
prepare() {
cd $pkgname
go build -v -mod=vendor -trimpath -buildmode=pie -ldflags="-s -w -extldflags $LDFLAGS"
}
package() {
cd $pkgname
install -Dm755 algernon "$pkgdir/usr/bin/algernon"
install -d "$pkgdir/usr/share/doc/$pkgname/samples"
cp -r samples "$pkgdir/usr/share/doc/$pkgname/samples"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
cd system
install -Dm644 logrotate "$pkgdir/etc/logrotate.d/algernon"
install -Dm644 serverconf.lua "$pkgdir/etc/algernon/serverconf.lua"
install -Dm644 algernon_dev.service "$pkgdir/usr/share/doc/$pkgname/algernon.service.example"
cd ../desktop
install -Dm755 mdview "$pkgdir/usr/bin/mdview"
install -Dm644 algernon.desktop "$pkgdir/usr/share/applications/algernon.desktop"
install -Dm644 algernon_md.desktop "$pkgdir/usr/share/applications/algernon_md.desktop"
install -Dm644 markdown.png "$pkgdir/usr/share/pixmaps/markdown.png"
}
|