PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Zeno Sebastian Endemann <zeno.endemann@mailbox.org>

pkgname=alpela
pkgver=5
pkgrel=1
pkgdesc='Experimental minimalist audio player'
arch=('x86_64')
url='https://gitlab.com/z-s-e/alpela'
license=('GPL-3.0-or-later')
depends=('alsa-lib' 'ffmpeg' 'hicolor-icon-theme' 'qt6-base' 'gcc-libs' 'glibc')
makedepends=('git' 'cmake')
optdepends=('realtime-privileges: allow realtime operation')
source=('git+https://gitlab.com/z-s-e/alpela.git#commit=3c4fbef67488878cc607651c9b52a6d5364d84a3'
        'git+https://gitlab.com/z-s-e/alpe.git'
        'git+https://github.com/z-s-e/lbu.git')
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

prepare() {
    cd ${pkgname}
    git submodule init
    git config submodule.deps/alpe.url "$srcdir/alpe"
    git config submodule.deps/lbu.url "$srcdir/lbu"
    git -c protocol.file.allow=always submodule update
}

build() {
    cmake \
        -G 'Unix Makefiles' \
        -B "${pkgname}-${pkgver}-build" \
        -S "${pkgname}" \
        -DCMAKE_BUILD_TYPE:STRING='None' \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -Wno-dev
    cmake --build "${pkgname}-${pkgver}-build"
}

package() {
    DESTDIR="${pkgdir}" cmake --install "${pkgname}-${pkgver}-build"
}