PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

pkgname='alsa-scarlett-gui-dev'
_pkgname='alsa-scarlett-gui'
pkgver=0.4.1.test1.8.g9fa6
pkgrel=1
pkgdesc="GUI for the ALSA controls presented by the Scarlett2 driver, Development version"
arch=('i686' 'x86_64')
url="https://github.com/geoffreybennett/alsa-scarlett-gui"
license=('GPL-3.0-or-later' 'LGPL-3.0-or-later')
depends=(
    'glibc'
    'glib2'
    'alsa-lib'
    'gtk4'
    'hicolor-icon-theme'
    'cairo'
    'openssl'
)
makedepends=('gcc' 'make' 'git' 'pkgconf' 'sed')
provides=("$_pkgname")
source=("git+${url}.git#branch=dev")
sha256sums=('SKIP')

pkgver() {
    cd "$_pkgname"
    git describe --abbrev=4 --always --tags | sed 's/-/./g'
}

build() {
    cd "$srcdir/$_pkgname"

    make \
        -C src \
        PREFIX=/usr \
        VERSION="$pkgver"
}

package() {
    cd "$srcdir/$_pkgname"

    make \
        -C src \
        PREFIX="$pkgdir/usr" \
        VERSION="$pkgver" \
        install

    # documentation
    install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md ./docs/*.md
    install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname/img" img/*
    install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname/demo" demo/*
}