summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: cc5eea0699677872eaf5998485691e1b568c3c5f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Frederik “Freso” S. Olesen <freso.dk@gmail.com>

pkgname=amidstexporter
pkgver='1.44'
_jarfile='AmidstExporter.jar'
pkgrel=1
pkgdesc='Advanced Minecraft Interface and Data/Structure Tracking; fork with location export.'
arch=('any')
license=('GPL3')
url='http://www.buildingwithblocks.info/exportfromseed.html'
depends=('java-runtime')
optdepends=('minecraft: the game itself')
noextract=("$_jarfile")
changelog=ChangeLog
source=("https://github.com/Treer/AMIDST/releases/download/v${pkgver}/${_jarfile}"
        amidstexporter.sh
        amidstexporter.desktop)
md5sums=('9c7a369c34aaa5cc48d7456706cfc989'
         '365558c0aadf7a879ff8f4514943b10c'
         'abe95f51b3ec61a2ae371a05c6edfc1f')

prepare() {
    cd "$srcdir"

    # Extract icon
    bsdcpio --extract --make-directories --insecure 'amidst/resources/icon16.png' 'amidst/resources/icon32.png' 'amidst/resources/icon64.png' < "$_jarfile"
}

package() {
    cd "$srcdir"

    install -vDm755 'amidstexporter.sh'           "$pkgdir/usr/bin/amidstexporter"
    install -vDm644 'amidst/resources/icon16.png' "$pkgdir/usr/share/pixmaps/amidstexporter-16.png"
    install -vDm644 'amidst/resources/icon32.png' "$pkgdir/usr/share/pixmaps/amidstexporter-32.png"
    install -vDm644 'amidst/resources/icon64.png' "$pkgdir/usr/share/pixmaps/amidstexporter-64.png"
    ln -s ./amidstexporter-64.png "$pkgdir/usr/share/pixmaps/amidstexporter.png"
    install -vDm644 'amidstexporter.desktop'      "$pkgdir/usr/share/applications/amidstexporter.desktop"
    install -vDm644 "$_jarfile"                   "$pkgdir/usr/share/java/$pkgname/$_jarfile"
}

# vim:set ts=4 sw=4 et: