blob: 0014348807460d359b61a530426db438d4046925 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
_android_arch=armv7a-eabi
pkgname=android-${_android_arch}-libsoup3
pkgver=3.5.2
pkgrel=1
arch=('any')
pkgdesc="HTTP client/server library for GNOME (Android ${_android_arch})"
url="https://wiki.gnome.org/Projects/libsoup"
license=('LGPL')
groups=(android-libsoup3)
depends=("android-${_android_arch}-brotli"
"android-${_android_arch}-libnghttp2"
"android-${_android_arch}-libpsl"
"android-${_android_arch}-sqlite")
makedepends=('android-meson'
'gobject-introspection')
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://gitlab.gnome.org/GNOME/libsoup/-/archive/${pkgver}/libsoup-${pkgver}.tar.bz2")
md5sums=('0fcaeddb7f0f859663857409745b61e6')
build() {
cd "${srcdir}/libsoup-${pkgver}"
source android-env ${_android_arch}
android-${_android_arch}-meson build \
-Dautobahn=disabled \
-Dvapi=disabled \
-Ddocs=disabled \
-Ddoc_tests=false \
-Dtests=false \
-Dsysprof=disabled \
-Dpkcs11_tests=disabled \
-Dtls_check=false \
-Dintrospection=disabled
ninja -C build
}
package() {
cd "${srcdir}/libsoup-${pkgver}"
source android-env ${_android_arch}
DESTDIR="${pkgdir}" meson install -C build
rm -rf "${pkgdir}/${ANDROID_PREFIX_SHARE}"
${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a || true
}
|