blob: 285b461404fc83b71147cc05c395ae65599a1291 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Federico Quagliata (quaqo) <quaqo@despammed.com>
_android_arch=x86-64
pkgname=android-${_android_arch}-cracklib
pkgver=2.9.11
pkgrel=1
arch=('any')
pkgdesc="Password Checking Library (android)"
license=('GPL')
url="https://github.com/cracklib/cracklib"
depends=("android-${_android_arch}-zlib")
makedepends=("cracklib")
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://github.com/cracklib/cracklib/releases/download/v$pkgver/cracklib-$pkgver.tar.gz")
sha256sums=('6213b986a5209fc0d4ca93734e349b8f66b36bfe9a3fae6eead14a15d82a68dc')
build() {
cd "${srcdir}/cracklib-$pkgver"
source android-env ${_android_arch}
android-${_android_arch}-configure \
--without-python
make $MAKEFLAGS
}
package() {
cd "${srcdir}/cracklib-$pkgver"
source android-env ${_android_arch}
make DESTDIR="$pkgdir" install
rm -rf "$pkgdir/${ANDROID_PREFIX}/sbin"
rm -rf "$pkgdir/${ANDROID_PREFIX_SHARE}/man"
${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}"/${ANDROID_PREFIX_LIB}/*.so
${ANDROID_STRIP} -g "$pkgdir"/${ANDROID_PREFIX_LIB}/*.a
# symlink cracklib-small #34778
mkdir -p "$pkgdir/${ANDROID_PREFIX_SHARE}/dict"
ln -sf ../cracklib/cracklib-small "$pkgdir/${ANDROID_PREFIX_SHARE}/dict/cracklib-small"
cracklib-format dicts/cracklib-small \
| cracklib-packer "$pkgdir/${ANDROID_PREFIX_SHARE}/cracklib/pw_dict"
}
|