blob: 6604473626952ac014571a21f2285074e7d721a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Daniel Bermond <dbermond@archlinux.org>
# Contributor: Chocobo1 <chocobo1@archlinux.net>
_android_arch=x86
pkgname=android-${_android_arch}-rav1e
pkgver=0.7.1
pkgrel=1
arch=('any')
pkgdesc="An AV1 encoder focused on speed and safety (Android ${_android_arch})"
url="https://github.com/xiph/rav1e/"
license=('custom:BSD')
depends=('android-ndk')
makedepends=('android-rust'
'nasm')
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://github.com/xiph/rav1e/archive/refs/tags/v${pkgver}.tar.gz"
"Cargo-rav1e-${pkgver}.lock::https://github.com/xiph/rav1e/releases/download/v${pkgver}/Cargo.lock")
md5sums=('2e48f60bea23049a750f0721e30cdd54'
'3c8e14548d37d9fd0efad829bb979e76')
prepare() {
cd "${srcdir}/rav1e-$pkgver"
source android-rust-env ${_android_arch}
android_rust_prepare
cp -f "${srcdir}/Cargo-rav1e-${pkgver}.lock" Cargo.lock
cargo fetch \
--locked \
--manifest-path Cargo.toml
}
build() {
cd "${srcdir}/rav1e-$pkgver"
source android-rust-env ${_android_arch}
android_cargo_cbuild \
--no-default-features \
--features asm,threading,signal_support \
--manifest-path Cargo.toml
}
package() {
cd "${srcdir}/rav1e-$pkgver"
source android-rust-env ${_android_arch}
android_cargo_cinstall \
--destdir "${pkgdir}" \
--features asm,threading,signal_support \
--no-default-features
mv -f "${pkgdir}/${ANDROID_PREFIX_LIB}/librav1e.so".*.*.* "${pkgdir}/${ANDROID_PREFIX_LIB}/librav1e.so"
rm -f "${pkgdir}/${ANDROID_PREFIX_LIB}/librav1e.so".*
${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}"/${ANDROID_PREFIX_LIB}/*.so
${ANDROID_STRIP} -g "$pkgdir"/${ANDROID_PREFIX_LIB}/*.a
}
|