PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Bruno Pagani <archange@archlinux.org>

_android_arch=x86

pkgname=android-${_android_arch}-webp-pixbuf-loader
pkgver=0.2.7
pkgrel=2
arch=('any')
pkgdesc="WebM GDK Pixbuf Loader library (Android ${_android_arch})"
url="https://github.com/aruiz/webp-pixbuf-loader"
license=('LGPL')
groups=(android-webp-pixbuf-loader)
depends=("android-${_android_arch}-gdk-pixbuf2"
         "android-${_android_arch}-libwebp")
makedepends=('android-meson')
options=(!strip !buildflags staticlibs !emptydirs)
source=("${url}/archive/${pkgver}/webp-pixbuf-loader-${pkgver}.tar.gz")
sha256sums=('61ce5e8e036043f9d0e78c1596a621788e879c52aedf72ab5e78a8c44849411a')

build() {
    cd "${srcdir}/webp-pixbuf-loader-${pkgver}"
    source android-env ${_android_arch}

    android-${_android_arch}-meson build
    ninja -C build
}

package() {
    cd "${srcdir}/webp-pixbuf-loader-${pkgver}"
    source android-env ${_android_arch}

    DESTDIR="${pkgdir}" ninja -C build install
    find "${pkgdir}/${ANDROID_PREFIX_LIB}" -type f -name '*.so' -exec ${ANDROID_STRIP} -g --strip-unneeded {} \;
}