blob: ca6a125ff67c916e3cda3e9e324a6a5475a1cbb9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Mahdi Sarikhani <mahdisarikhani@outlook.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Jonathan Steel <jsteel at archlinux.org>
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: tocer.deng <tocer.deng@gmail.com>
pkgname=apvlv
pkgver=0.7.0_alpha
pkgrel=1
pkgdesc="A PDF/EPUB/TXT/FB2/MOBI/CBZ/HTML viewer which behaves like Vim"
arch=('x86_64')
url="https://github.com/naihe2010/apvlv"
license=('GPL-2.0-or-later')
depends=('djvulibre' 'gcc-libs' 'glibc' 'libmupdf' 'qt6-base' 'qt6-webengine' 'quazip-qt6' 'tesseract')
makedepends=('clang' 'cmake' 'ghostscript' 'libreoffice-sdk' 'man-db' 'qt6-tools')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver//_/-}.tar.gz")
sha256sums=('c763ff61eb4f907ce66747045e242a06d8ff36083d0ff5805277ce26a707e0fa')
build() {
mkdir -p "${pkgname}-${pkgver//_/-}/share/doc/apvlv/translations"
cmake -B build -S "${pkgname}-${pkgver//_/-}" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_PREFIX_PATH=/usr/lib/qt6 \
-Wno-dev
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
install -d "${pkgdir}/usr/share/man/man1"
mv "${pkgdir}/usr/share/man/apvlv.1" "${pkgdir}/usr/share/man/man1"
}
|