1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Contributor: Alexander 'hatred' Drozdov <adrozdoff@gmail.com>
# Contributor: toha257 <toha257@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: Tavian Barnes <tavianator@tavianator.com>
# Contributor: Vyacheslav Razykov <v.razykov@gmail.com>
# Maintainer: Wilken Gottwalt <wilken dot gottwalt at posteo dot net>
_target=arm-linux-gnueabihf
pkgname="${_target}-gcc"
pkgver=15.1.1.git+f36ec88aa85
_majorver="15.1.1"
_commit=f36ec88aa85a1a8f4ec300dfcd862fc4fbca1c53
_gmpver=6.3.0
_islver=0.26
_mpcver=1.3.1
_mpfrver=4.2.2
pkgrel=1
pkgdesc="The GNU Compiler Collection"
arch=(x86_64)
license=(GPL LGPL FDL custom)
url='https://gcc.gnu.org'
depends=("${_target}-binutils>=2.42" "${_target}-glibc>=2.40" elfutils zlib zstd)
makedepends=(base-devel glibc libelf python zlib zstd)
options=(!emptydirs !distcc !strip lto)
conflicts=("${_target}-gcc-stage1" "${_target}-gcc-stage2")
replaces=("${_target}-gcc-stage1" "${_target}-gcc-stage2")
provides=("${_target}-gcc-stage1=${pkgver}" "${_target}-gcc-stage2=${pkgver}")
source=(git+https://github.com/gcc-mirror/gcc.git#commit=${_commit}
https://gmplib.org/download/gmp/gmp-${_gmpver}.tar.xz{,.sig}
https://libisl.sourceforge.io/isl-${_islver}.tar.xz
https://ftp.gnu.org/gnu/mpc/mpc-${_mpcver}.tar.gz
https://www.mpfr.org/mpfr-${_mpfrver}/mpfr-${_mpfrver}.tar.xz{,.asc})
validpgpkeys=(F3691687D867B81B51CE07D9BBE43771487328A9 # bpiotrowski@archlinux.org
86CFFCA918CF3AF47147588051E8B148A9999C34 # evangelos@foutrelis.com
13975A70E63C361C73AE69EF6EEB81F8981C74C7 # richard.guenther@gmail.com
D3A93CAD751C2AF4F8C7AD516C35B99309B5FA62 # jakub@redhat.com
343C2FF0FBEE5EC2EDBEF399F3599FF828C67298 # nisse@lysator.liu.se
A534BE3F83E241D918280AEB5831D11A0D4DB02A) # vincent@vinc17.net
sha256sums=('7dc521dbaf5e8db83574db217c5fdb8c4fed6ec1cc6ce9f0095755f599890b8c'
'a3c2b80201b89e68616f4ad30bc66aee4927c3ce50e33929ca819d5c43538898'
'SKIP'
'a0b5cb06d24f9fa9e77b55fabbe9a3c94a336190345c2555f9915bb38e976504'
'ab642492f5cf882b74aa0cb730cd410a81edcdbec895183ce930e706c1c759b8'
'b67ba0383ef7e8a8563734e2e889ef5ec3c3b898a01d00fa0a6869ad81c6ce01'
'SKIP')
pkgver() {
cd gcc
local _hash="$(git rev-parse --short ${_commit})"
echo "${_majorver}.git+${_hash}"
}
prepare() {
cd gcc
mv ../gmp-${_gmpver} gmp
mv ../isl-${_islver} isl
mv ../mpc-${_mpcver} mpc
mv ../mpfr-${_mpfrver} mpfr
sed -i 's@\./fixinc\.sh@-c true@' gcc/Makefile.in
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" {libiberty,gcc}/configure
mkdir -p "${srcdir}"/gcc-build
}
build() {
cd gcc-build
# using -Werror=format-security causes libcpp buildig failures
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=100207
CFLAGS="${CFLAGS/-Werror=format-security/}"
CXXFLAGS="${CXXFLAGS/-Werror=format-security/}"
../gcc/configure \
--target=${_target} \
--host=${CHOST} \
--build=${CHOST} \
--prefix=/usr \
--program-prefix=${_target}- \
--libdir=/usr/lib \
--libexecdir=/usr/lib \
--with-local-prefix=/usr/${_target} \
--with-sysroot=/usr/${_target} \
--with-build-sysroot=/usr/${_target} \
--with-native-system-header-dir=/include \
--with-as=/usr/bin/${_target}-as \
--with-ld=/usr/bin/${_target}-ld \
--with-linker-hash-style=gnu \
--with-system-zlib \
--with-arch=armv6 \
--with-float=hard \
--with-fpu=vfp \
--enable-languages=c,c++,lto,m2 \
--enable-__cxa_atexit \
--enable-cet=auto \
--enable-checking=release \
--enable-clocale=gnu \
--enable-default-pie \
--enable-default-ssp \
--enable-gnu-indirect-function \
--enable-gnu-unique-object \
--enable-libstdcxx-backtrace \
--enable-link-serialization=1 \
--enable-linker-build-id \
--enable-lto \
--enable-plugin \
--enable-shared \
--enable-threads=posix \
--enable-libquadmath \
--enable-libvtv \
--disable-nls \
--disable-install-libiberty \
--disable-libssp \
--disable-libstdcxx-pch \
--disable-multilib \
--disable-werror
make
}
package() {
cd gcc-build
make DESTDIR="${pkgdir}" install-gcc install-target-{libatomic,libgcc,libgm2,libgomp,libitm,libquadmath,libsanitizer,libstdc++-v3,libvtv}
rm -rf "${pkgdir}"/usr/share/{gcc-${_majorver},info,man/man7}
# strip it manually
find "${pkgdir}"/usr -type f -exec /usr/bin/"${_target}"-strip --strip-unneeded {} \; 2>/dev/null || true
find "${pkgdir}"/usr -type f -and \( -executable \) -exec /usr/bin/"${_target}"-strip --strip-unneeded {} \; 2>/dev/null || true
find "${pkgdir}"/usr -type f -exec /usr/bin/strip --strip-unneeded {} \; 2>/dev/null || true
find "${pkgdir}"/usr -type f -and \( -executable \) -exec /usr/bin/strip --strip-unneeded {} \; 2>/dev/null || true
}
|