blob: 001c0c6fe513927e7d48d706b74f98249c20ccf7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# $Id$
# Maintainer: Timo Sarawinski <t.sarawinski@gmail.com>
_target=arm-none-eabi
pkgname=$_target-linaro-binutils
pkgver=2.42
pkgrel=1
#_commit=2bd25930
pkgdesc='A set of pograms to assemble and manipulate binary and object files for the ARM EABI target with extra flags'
arch=(x86_64)
url='http://www.gnu.org/software/binutils/'
license=(GPL)
depends=('libisl' 'cloog' 'gmp' 'mpc' 'mpfr' 'zlib')
makedepends=('perl')
provides=('arm-none-eabi-binutils')
conflicts=('arm-none-eabi-binutils')
source=(ftp://ftp.gnu.org/gnu/binutils/binutils-$pkgver.tar.bz2{,.sig})
sha1sums=('ead6f01f47cf1a6c39bfaf83ab84ac99bc6d70c8'
'SKIP')
validpgpkeys=('EAF1C276A747E9ED86210CBAC3126D3B4AE55E93' # Tristan Gingold <gingold@adacore.com>
'3A24BC1E8FB409FA9F14371813FCEF89DD9E3C4F'
'13FCEF89DD9E3C4F') # Nick Clifton (Chief Binutils Maintainer) <nickc@redhat.com>
prepare() {
cd binutils-$pkgver
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
}
build() {
cd binutils-$pkgver
if [ "${CARCH}" != "i686" ]; then
# enabling gold linker at i686 makes the install fail
enable_gold='--enable-gold'
fi
./configure --target=$_target \
--with-sysroot=/usr/$_target \
--prefix=/usr \
--enable-multilib \
--enable-interwork \
--with-gnu-as \
--with-gnu-ld \
--enable-lto \
--enable-vtable-verify \
--disable-nls \
--enable-ld=default \
$enable_gold \
--enable-plugins \
--enable-deterministic-archives
make
}
check() {
cd binutils-$pkgver
# unset LDFLAGS as testsuite makes assumptions about which ones are active
# do not abort on errors - manually check log files
make LDFLAGS="" -k check || true
}
package() {
cd binutils-$pkgver
make DESTDIR="$pkgdir" install
# Remove file conflicting with host binutils and manpages for MS Windows tools
rm "$pkgdir"/usr/share/man/man1/arm-none-eabi-{dlltool,windres,windmc}*
# Remove info documents that conflict with host version
rm -r "$pkgdir"/usr/share/info
}
|