blob: cfcbb761bb61e9d39310bfcdfaf131c78d7fe7db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Joey Dumont <joey.dumont@gmail.com>
# Contributor: Lucas Hermann Negri <lucashnegri at gmail dot com>
pkgname=armadillo
pkgver=11.2.3
_pkgver=${pkgver/_/-} # For use with RC releases, to replace the _ with -
pkgrel=1
pkgdesc="C++ linear algebra library"
arch=('i686' 'x86_64')
url="http://arma.sourceforge.net/"
license=('Apache')
depends=('lapack' 'blas' 'arpack' 'superlu>=5.2.0')
optdepends=('hdf5: HDF5 output'
'intel-mkl: Intel Math Kernel Library support')
makedepends=('cmake')
source=("http://downloads.sourceforge.net/sourceforge/arma/$pkgname-$_pkgver.tar.xz")
install=armadillo.install
sha512sums=('db3457adbc799c68c928aaf22714598b4b9df91ec83aff33bf2d0096b755bd316d4bae12ac973bf1821759a71f3a58a7dd8dc64cbcb1f53ea2646d8bb0bc9a3b')
build() {
if [ "$CARCH" == "x86_64" ]; then
ARMA64LIBDIR="-DINSTALL_LIB_DIR:PATH=/usr/lib"
fi
cd "${srcdir}/$pkgname-$_pkgver"
cmake $ARMA64LIBDIR -DCMAKE_INSTALL_PREFIX:PATH=/usr .
make
}
package() {
cd "${srcdir}/$pkgname-$_pkgver"
make DESTDIR="${pkgdir}" install
install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|