blob: 641021e18ae58093c1943b81d8e11f2d33d15768 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: KokaKiwi <kokakiwi+aur [at] kokakiwi dot com>
# Contributor: Mike Yuan <me@yhndnzj.com>
pkgbase=ast-grep
pkgname=(ast-grep python-ast-grep)
pkgver=0.36.2
pkgrel=1
pkgdesc='A fast and polyglot tool for code structural search, lint, rewriting at large scale'
arch=('x86_64')
url='https://ast-grep.github.io/'
license=('MIT')
depends=('gcc-libs')
makedepends=('cargo' 'python-build' 'python-installer' 'python-wheel' 'python-maturin')
checkdepends=('python')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/ast-grep/ast-grep/archive/$pkgver.tar.gz")
sha256sums=('f18b3f176308072e6923c19b818167e04f1411dc016fe55b585f505edcec7c6b')
b2sums=('0e71f36f55437280fd761e5bb26cd4a3e880dcc016bb1d6236eb654ccc5320c85b119c97512b5d5618e1eff789b559d153c4e2ae36046d3a4cabd099d1a396db')
options=('!lto')
export RUSTUP_TOOLCHAIN=${RUSTUP_TOOLCHAIN:-stable}
prepare() {
cd "$pkgbase-$pkgver"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgbase-$pkgver"
CARGO_TARGET_DIR=target \
cargo build --frozen --release --all-features --package ast-grep --bin ast-grep
cd crates/pyo3
python -m build --wheel --no-isolation
}
check() {
cd "$pkgbase-$pkgver"
RUSTFLAGS="$RUSTFLAGS -C debug-assertions" cargo test --frozen --all-features
}
package_ast-grep() {
cd "$pkgbase-$pkgver"
install -Dm0755 -t "$pkgdir/usr/bin" \
target/release/ast-grep
ln -sf ast-grep "$pkgdir/usr/bin/asg"
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" \
LICENSE
}
package_python-ast-grep() {
depends=('python')
cd "$pkgbase-$pkgver"
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" \
LICENSE
cd crates/pyo3
python -m installer --destdir="$pkgdir" dist/*.whl
}
|