PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Hurstel Alexandre <a.hurstel@unistra.fr>

pkgname=astex-git
pkgver=r461.3c1e70c
pkgrel=1
pkgdesc="ASTex is an open-source library for texture analysis and synthesis."
arch=(i686 x86_64)
url="https://astex-icube.github.io"
license=(LGPL-2.1-or-later)
depends=()
makedepends=(git cmake cgal glfw glu glew eigen boost insight-toolkit libpng openexr suitesparse onetbb)
provides=(astex)
conflicts=(astex)
options=(!lto)
source=("git+https://github.com/ASTex-ICube/ASTex.git")
b2sums=('SKIP')

pkgver() {
  cd "ASTex"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  export CFLAGS+=" -Wno-error=format-security"
  export CXXFLAGS+=" -Wno-error=format-security"

  cmake -B build -S "ASTex" -Wno-dev \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr

  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}