summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: af4eabfe0144f7a52c9dde47246e2dba7bc9e3b8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Brian Bidulock <bidulock@openss7.org>

pkgname=aumix
pkgver=2.9.1
pkgrel=9
pkgdesc="A color text mode sound mixer with GPM support"
arch=('x86_64' 'i686')
license=('GPL')
depends=()
makedepends=('gtk2' 'gpm' 'ncurses')
optdepends=('gtk2: aumix'
	    'ncurses: aumix-nox'
	    'gpm: aumix-nox')
replaces=('aumix-gtk')
provides=('aumix-gtk')
url="http://www.jpj.net/~trevor/aumix.html"
source=(http://www.jpj.net/~trevor/aumix/releases/aumix-$pkgver.tar.bz2
	aumix.desktop)
md5sums=('34f28ae1c94fc5298e8bb2688c4b3a20'
         'afba8b39b8dd95d8a9d74356023de14a')

build() {
  cd "$srcdir"
  cp -a aumix-$pkgver aumix-gtk-$pkgver

  cd "$srcdir"/aumix-$pkgver
  msg "No X11 build"
  ./configure --prefix=/usr --mandir=/usr/share/man --without-gtk --without-gtk1 \
	--without-alsa --without-x
  make

  cd "$srcdir"/aumix-gtk-$pkgver
  msg "X11+GTK2 build"
  ./configure --prefix=/usr --mandir=/usr/share/man --without-gtk1 --without-alsa \
	--without-gpm
  make
}

package() {
  cd "$srcdir"/aumix-$pkgver
  install -D -m0755 src/aumix "$pkgdir"/usr/bin/aumix-nox

  cd "$srcdir"/aumix-gtk-$pkgver
  make DESTDIR="$pkgdir" install
  install -D -m0644 "$srcdir"/aumix.desktop "$pkgdir"/usr/share/applications/aumix.desktop
}