PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Hans-Nikolai Viessmann <hans AT viess DOT mn>
pkgname=barvinok
pkgver=0.41.8
pkgrel=1
pkgdesc='A library for counting the number of integer points in (non-)parametric polytopes'
arch=('x86_64')
url='https://repo.or.cz/barvinok.git'
license=('GPL-2.0-only')
depends=('ntl' 'libisl>0.19' 'polylib-gmp')
makedepends=('git')
source=("git+https://repo.or.cz/barvinok.git#tag=$pkgname-$pkgver")
sha256sums=('SKIP')

prepare () {
    cd "$srcdir/$pkgname"

    # setup the repo
    ./get_submodules.sh
    ./autogen.sh
}

build() {
    cd "$srcdir/$pkgname"

    # NTL 11 now uses pthread functions, so we need to have it link to libpthread.
    ./configure --prefix=/usr --enable-shared-barvinok --with-isl=system --with-polylib=system LIBS="-lpthread"
    make
}

check() {
    cd "$srcdir/$pkgname"
    make check
}

package() {
    cd "$srcdir/$pkgname"
    make DESTDIR="$pkgdir" install
}