PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Nicola Revelant <nicolarevelant@outlook.com>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: lucke <lucke at o2 dot pl>

pkgname=basket
_pkgver=2.49
pkgver=${_pkgver}b
pkgrel=9
pkgdesc="All-purpose notes taker"
arch=('x86_64')
url="https://basket-notepads.github.io/"
license=('GPL')

depends=(
	kcmutils5
	kfilemetadata5
	kparts5
	libgit2
	phonon-qt5
)

makedepends=(
	extra-cmake-modules
	kdoctools5
	ninja
)

source=(https://launchpad.net/basket/kde5/$pkgver/+download/basket-$_pkgver-beta.tar.bz2
        basket-libgit2-0.99.patch::"https://invent.kde.org/utilities/basket/-/commit/090ac469.patch")

sha256sums=('e760fc68deb1f56ef02cd4a1773c6cd348b79b88ef5ff5dfb05e66947244f186'
            '28437b7833806ecbef9ae62429d96ee20216c37eaba352a40e6b98949c6abcf0')

prepare() {
	patch -d $pkgname-$_pkgver-beta -p1 < basket-libgit2-0.99.patch # Fix build with libgit>=0.99
}

build() {
	cmake -B build -G Ninja -S $pkgname-$_pkgver-beta -DBUILD_TESTING=OFF
	cmake --build build
}

package() {
	DESTDIR="$pkgdir" cmake --install build
}