blob: 4fbbf87fcc17bd805fbf40f1f4167e58e5277009 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=bat-extras
pkgver=2021.08.21
pkgrel=2
pkgdesc="Bash scripts that integrate bat with various command line tools"
arch=('any')
url="https://github.com/eth-p/bat-extras"
license=('MIT')
depends=('bat' 'bash' 'git' 'ripgrep' 'man-db')
optdepends=(
'ncurses: optional for batdiff script'
'git-delta: optional for batdiff script'
'fzf: optional for batman script'
'exa: optional for batpipe script'
'entr: optional for batwatch script'
'prettier: various code formatting for prettybat script'
'shfmt: bash formatting for prettybat script'
'rustfmt: Rust formatting for prettybat script'
'clang: C / C++ / Objective-C formatting for prettybat script'
'python-black: Python formatting for prettybat script'
)
checkdepends=('fish')
_commit='7803ecaba1e78adacc277e82b2568cca007b1ba0'
source=("git+$url.git#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^[vV]//;s/-/+/g'
}
prepare(){
cd "$pkgname"
git submodule update --init --recursive
}
check() {
cd "$pkgname"
./test.sh --verbose --strict --snapshot:show
}
package() {
cd "$pkgname"
./build.sh \
--minify=none \
--no-verify \
--prefix="$pkgdir/usr" \
--install
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
CONTRIBUTING.md README.md doc/*
install -vDm644 -t "$pkgdir/usr/share/man/man1" man/*
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
}
|