blob: 4eb1cc8b172144cdb3d65b316f8e38dba51be5c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Amolith <amolith@secluded.site>
pkgname=beats-swatch-git
_pkgname=${pkgname%-git}
_binname=${_pkgname%-swatch}
pkgdesc='Go library for all your Swatch Internet Time needs (command)'
arch=("any")
url="https://github.com/peterhellberg/beats.git"
uri="github.com/peterhellberg/beats"
_branch='master'
pkgver=r8.9151836
pkgrel=1
license=("MIT")
makedepends=("git" "go")
source=("$pkgname::git+$url#branch=$_branch")
sha256sums=("SKIP")
provides=($_pkgname)
conflicts=($_pkgname)
pkgver() {
cd "$pkgname"
( set -o pipefail
git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
)
}
build() {
cd $pkgname
export CGO_LDFLAGS="${LDFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go mod init $uri
go mod tidy
go build -o "$_binname" ./cmd/$_binname
}
check() {
cd "$pkgname"
go test ./cmd/$_binname
}
package() {
cd "$pkgname"
install -Dm755 "$_binname" "$pkgdir/usr/bin/$_binname"
sed -n '/---/q;p' README.md | sed 's/^> //' | tail -19 > LICENSE
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_binname/LICENSE"
}
|