blob: 00bfcb3b1bff2bf2602b18f2c4d4f44f4560bc7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- mode: sh -*-
_pkgname='betula'
pkgname="$_pkgname-git"
pkgver=1.2.0.r55.ge83a303
pkgrel=1
pkgdesc='Federated personal link collection manager (built from latest commit)'
arch=('aarch64' 'armv7h' 'x86_64')
url="https://git.sr.ht/~bouncepaw/$_pkgname"
license=('AGPL-3.0-or-later') # SPDX-License-Identifier: AGPL-3.0-or-later
depends=('glibc')
makedepends=('git' 'go')
source=("git+$url")
provides=("$_pkgname")
conflicts=("$_pkgname")
sha256sums=('SKIP')
options=('lto')
prepare() {
cd "$_pkgname"
mkdir -p build
go mod tidy
}
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
# RFC-0023
# 🔗 https://rfc.archlinux.page/0023-pack-relative-relocs/
#
# ld(1) says: “Supported for i386 and x86-64.”
case "Z${CARCH:-unknown}" in
'Zx86_64' | 'Zi386' )
export LDFLAGS="$LDFLAGS -Wl,-z,pack-relative-relocs"
;;
* ) : pass ;;
esac
export CGO_ENABLED=1
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS -D_LARGEFILE64_SOURCE"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
go build \
-buildmode=pie \
-trimpath \
-ldflags="-linkmode=external -X main.version=$pkgver" \
-mod=readonly \
-modcacherw \
-o build \
./cmd/betula
}
package() {
cd "$_pkgname"
install -vDm0755 "build/betula" "$pkgdir/usr/bin/betula"
install -vDm0644 "FEDERATION.md" "$pkgdir/usr/share/doc/$pkgname/FEDERATION.md"
install -vDm0644 "README.md" "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# eof
|