blob: 1a7b2f018be265641a75a961f815dd5619689549 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: libertylocked <libertylocked@disroot.org>
# Contributor: Milo Gilad <myl0gcontact@gmail.com>
pkgname=bitwarden
pkgver=1.17.2
pkgrel=1
_jslibcommit='31a257407be7f8f47624b0d021363aaf2cfda2d7'
_nodeversion='10.19.0'
pkgdesc='Bitwarden Desktop Application'
arch=('x86_64')
url='https://github.com/bitwarden/desktop'
license=('GPL3')
makedepends=('expac' 'git' 'npm' 'nvm' 'jq' 'patch')
depends=('alsa-lib' 'electron' 'gtk2' 'libnotify' 'libsecret' 'libxss' 'libxtst' 'nss')
conflicts=('bitwarden-git' 'bitwarden-bin')
options=('!strip' '!emptydirs')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/bitwarden/desktop/archive/v${pkgver}.tar.gz"
"jslib-${_jslibcommit}.tar.gz::https://github.com/bitwarden/jslib/archive/${_jslibcommit}.tar.gz"
"package.json.patch"
"${pkgname}.sh"
"${pkgname}.desktop")
sha512sums=('2fb1300f8a824c240a4fa6f26a950a0994386df9491408176f1a8397747457cb9e6c2e24d29add0184e7b3c29a01e9c86b686cdc923028abed6381a430507757'
'3103cfaae0b46f4c32ce4c70ef2ef34ec96048cd480151b381add63b82d57e1c1c385ef72a998999f077b3c23008eb995a18d8f829bae95e89fb8b2348e0840b'
'b6b4b52ab3ab8e4ae726bbfad0027a0de0978bbf427bfe7582561114ad421f6778d83661423fac712f920cfac18d4045961591e00df3587fbf95942fa70ee50b'
'724b548688e2af1d8d25e6ebe6e35831e891453f2df011e5fa757b57fcbcfef3c171510be4537652891441c65121bd9766f372f82d3edd5971fb77b726409575'
'05b771e72f1925f61b710fb67e5709dbfd63855425d2ef146ca3770b050e78cb3933cffc7afb1ad43a1d87867b2c2486660c79fdfc95b3891befdff26c8520fd')
prepare() {
# Link jslib
rmdir "${srcdir}/desktop-${pkgver}/jslib"
ln -s "${srcdir}/jslib-${_jslibcommit}" "${srcdir}/desktop-${pkgver}/jslib"
cd "${srcdir}/desktop-${pkgver}"
# Patch out postinstall routines
patch --strip=1 package.json ${srcdir}/package.json.patch
# Patch build to make it work with system electron
SYSTEM_ELECTRON_VERSION=$(expac %v electron | cut -d'-' -f1)
jq < package.json --arg ver $SYSTEM_ELECTRON_VERSION\
'.build["electronVersion"]=$ver | .build["electronDist"]="/usr/lib/electron"'\
> package.json.patched
mv package.json.patched package.json
}
build() {
export npm_config_cache="$srcdir/npm_cache"
_npm_prefix=$(npm config get prefix)
npm config delete prefix
source /usr/share/nvm/init-nvm.sh
nvm install ${_nodeversion} && nvm use ${_nodeversion}
cd "${srcdir}/desktop-${pkgver}/jslib"
npm install
cd "${srcdir}/desktop-${pkgver}"
npm install
npm run build
npm run clean:dist
npx electron-builder --dir build
# Restore node config from nvm
npm config set prefix ${_npm_prefix}
nvm unalias default
}
package() {
cd "${srcdir}/desktop-${pkgver}"
install -dm755 "${pkgdir}/usr/lib/${pkgname}"
cp -r dist/linux-unpacked/resources "${pkgdir}/usr/lib/${pkgname}/"
install -dm755 "${pkgdir}/usr/share/icons/hicolor"
for i in 16 32 48 64 128 256 512; do
install -Dm644 resources/icons/${i}x${i}.png "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
done
install -dm755 "${pkgdir}/usr/bin"
install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/bitwarden-desktop"
install -Dm644 "${srcdir}"/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
}
|