blob: 939ead8a5492acc7526b6e887b8c530f5c83c248 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: libertylocked <libertylocked@disroot.org>
# Contributor: Milo Gilad <myl0gcontact@gmail.com>
pkgname=bitwarden
pkgver=1.14.0
pkgrel=3
_jslibcommit='49e06e77c4913867fc468f7d9e0b2b1529c1d181'
pkgdesc='Bitwarden Desktop Application'
arch=('x86_64')
url='https://github.com/bitwarden/desktop'
license=('GPL3')
makedepends=('npm' 'nvm')
depends=('alsa-lib' 'gconf' 'gtk2' 'libnotify' 'libsecret' 'libxss' 'libxtst' 'nspr' 'nss')
conflicts=('bitwarden-git' 'bitwarden-bin')
options=('!strip' '!emptydirs')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/bitwarden/desktop/archive/v${pkgver}.tar.gz"
"jslib-${_jslibcommit}.tar.gz::https://github.com/bitwarden/jslib/archive/${_jslibcommit}.tar.gz"
"${pkgname}.desktop")
sha512sums=('245d81a87fef13c2e6c69de66511f5b404d1f53659efd621473d1390576b3e9f7b639520095fa9544dd5ec97ca11785d8151560c62562f10f06adc6adc8f5280'
'89428796d35edd09648814ed8a89b72e95b47a1a5b830855da2a319236e4fae74812f7cd5326ec7c56c87a038ba2d73ac9352764c950a362c2617e21e617b902'
'05b771e72f1925f61b710fb67e5709dbfd63855425d2ef146ca3770b050e78cb3933cffc7afb1ad43a1d87867b2c2486660c79fdfc95b3891befdff26c8520fd')
prepare() {
rmdir "${srcdir}/desktop-${pkgver}/jslib"
ln -s "${srcdir}/jslib-${_jslibcommit}" "${srcdir}/desktop-${pkgver}/jslib"
sed -i 's/ && npm run sub:init//' "${srcdir}/desktop-${pkgver}/package.json"
}
build() {
export npm_config_cache="$srcdir/npm_cache"
_npm_prefix=$(npm config get prefix)
npm config delete prefix
source /usr/share/nvm/init-nvm.sh
nvm install 10.15.3 && nvm use 10.15.3
cd "${srcdir}/desktop-${pkgver}/jslib"
npm install
cd "${srcdir}/desktop-${pkgver}"
npm install
npm run build
npm run clean:dist
# Make unpacked dist using electron-builder.
# Don't use `npm run dist:lin` because it builds a bunch of other irrelevant
# platforms as it uses the config in package.json
npx build --dir build
# Restore node config from nvm
npm config set prefix ${_npm_prefix}
nvm unalias default
}
package() {
cd "${srcdir}/desktop-${pkgver}"
install -dm755 "${pkgdir}/usr/lib/${pkgname}"
# Unfortunately we have to copy the bundled electron now
# Since electron3 is no longer in arch community
cp -a dist/linux-unpacked/. "${pkgdir}/usr/lib/${pkgname}/"
install -dm755 "${pkgdir}/usr/share/icons/hicolor"
for i in 16 32 48 64 128 256 512; do
install -Dm644 resources/icons/${i}x${i}.png "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
done
install -dm755 "${pkgdir}/usr/bin"
ln -sf "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}-desktop"
install -Dm644 "${srcdir}"/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
}
|