blob: d7adb2d7986852cad627bb06171f3ea2aee70914 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
pkgname=blis-openmp-git
pkgver=r1719.171f1006
pkgrel=1
pkgdesc="BLAS-like Library Instantiation Software Framework (with OpenMP support)"
arch=('i686' 'x86_64')
license=('custom')
url="https://github.com/flame/blis"
makedepends=('git' 'make' 'gcc' 'python')
provides=('blis')
conflicts=('blis' 'blis-git')
source=("$pkgname::git+https://github.com/flame/blis.git")
sha1sums=('SKIP')
options=('staticlibs')
pkgver() {
cd "${pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${pkgname}"
# static build is necessary for some packages and programs (e. g. GAMESS)
./configure --prefix=/usr --enable-static --enable-shared --enable-threading=openmp auto
make
}
check() {
cd "${pkgname}"
make check
}
package() {
cd "${pkgname}"
make DESTDIR="${pkgdir}" install
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"
}
|