PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Nikolaos Bezirgiannis

pkgname=blst-git
pkgver=0.3.11.r10.g9c87d4a
pkgrel=1
pkgdesc='Multilingual BLS12-381 signature library'
arch=('aarch64' 'x86_64')
url='https://github.com/supranational/blst'
license=('Apache')
depends=('glibc')
makedepends=('git')
provides=("blst=$pkgver")
conflicts=('blst')
source=("git+https://github.com/supranational/blst.git")
options=('staticlibs')
sha256sums=('SKIP')


pkgver() {
  cd "blst"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
cd "blst"
./build.sh -shared
}

package() {
cd "blst"
install -Dm755 -t "${pkgdir}/usr/lib" libblst.so
install -Dm644 -t "${pkgdir}/usr/lib" libblst.a
install -Dm644 -t "${pkgdir}/usr/include" bindings/*.h
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/blst/LICENSE"

mkdir -p ${pkgdir}/usr/lib/pkgconfig
cat <<EOF > ${pkgdir}/usr/lib/pkgconfig/libblst.pc
prefix=/usr
exec_prefix=\${prefix}
libdir=\${exec_prefix}/lib
includedir=\${prefix}/include

Name: libblst
Description: ${pkgdesc}
URL: ${url}
Version: ${pkgver}

Cflags: -I\${includedir}
Libs: -L\${libdir} -lblst
Libs.private:
EOF
}